• 採用実績は20000作品以上。PC・スマホ・ブラウザ対応のノベルゲーム製作キット
クイック検索

タグリファレンス(V４)

V５はこちら
ティラノスクリプトのタグ一覧。英語版は 「English TyranoScript Tags Reference 」

基本

[ ] で囲まれた部分がタグになります。
@で始まる行も、タグとして認識しますが、１行で記述しなければなりません
;(セミコロン)で始まる行はコメントとして扱われます。
複数行にわたってコメントにする場合は、/* からはじめて */ で 閉じることでコメントになります。　
すべてのタグにcond属性があります。JS式を記述して、その結果が真の場合のみタグが実行されます
_（半角アンダーバー）で始まる行は、文章の前に空白を挿入することができます。

[config_record_label]　既読管理の設定

  • システム操作

既読管理に関する設定を変更できます

パラメータ必須解説
color × 既読時のテキスト色を0x000000形式で指定してください
skip × 未読スキップをの有効(true)、無効(false)を指定します。つまりfalseを指定すると、未読文章で止まります。

[l]　クリック待ち

  • メッセージ関連

このタグの位置でクリック待ちを行います。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

テキスト表示[l]
テキスト表示[l][r]

[p]　改ページクリック待ち

  • メッセージ関連

改ページをともなうクリック待ちで使用できます

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

テキスト表示[p]
テキスト表示[p][r]

[graph]　インライン画像表示

  • メッセージ関連

任意の画像をメッセージ中に表示します。
絵文字や特殊文字などに活用できます。
表示させる画像はimageフォルダに配置して下さい

また、よく使う記号については、マクロを組んでおくと楽です。

パラメータ必須解説
storage ◯ 表示する画像ファイル名を指定します
  • サンプルコード

; heart にはハートマークの画像
[macro name="heart"][graph storage="heart.png"][endmacro]

; 以後、[heart] タグでハートマークを使用可能
大好き[heart]

[jump]　シナリオのジャンプ

  • ラベル・ジャンプ操作

指定されたファイルの指定されたラベルに移動します
callとの違いは、jumpはコールスタックに残りません。つまり、一方通行です。ラベルの指定は必須です。

パラメータ必須解説
storage × 移動するシナリオファイル名を指定します。省略された場合は現在のシナリオファイルと見なされます
target × ジャンプ先のラベル名を指定します。省略すると先頭から実行されます
  • サンプルコード


; second.ks というシナリオファイルの　*start　ラベルへ移動する
[jump storage=second.ks target=*start]


[r]　改行する

  • メッセージ関連

改行します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

テキスト表示[l]
改行します[l][r]
改行します[l][r]

[er]　メッセージレイヤの文字の消去

  • メッセージ関連

現在の操作対象メッセージレイヤ(current指定)の文字を消去します。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

テキスト表示[l]
メッセージをクリアします[l][er]
改行します[l][r]

[cm]　すべてのメッセージレイヤをクリア

  • メッセージ関連

すべてのメッセージレイヤをクリアします。
また、フォントスタイルなどもデフォルトの設定に戻ります。
ただし、positionやlayoptで指定した値は引き継がれます
[ct]タグのように 操作対象のメッセージレイヤが表ページの message0 に指定されるようなことはありません。 このタグを実行後も操作対象のレイヤは同じです。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

テキスト表示[l]
画面クリアする[l][cm]
もう一度画面クリアする[l][cm]

[ct]　すべてのメッセージレイヤをリセット

  • メッセージ関連


メッセージレイヤをリセットします。
すべてのメッセージレイヤの文字は消去され、操作対象のメッセージレイヤは 表ページの message0 に指定されます。
font タグで指定した文字の属性、style タグ で指定したスタイルはすべて標準状態に戻ります。ただ し、position タグ や layopt タグで指定した属性は引き継が れます。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

テキスト表示[l]
画面クリアする[l][ct]
もう一度画面クリアする[l][ct]

[current]　操作対象のメッセージレイヤの指定

  • メッセージ関連

操作対象とするメッセージレイヤを指定します。以後、文章や font タグでの文字属性の指定、l タグ等のクリック待ちなどは、このレイヤに対して行われます。
message0はデフォルトで可視の状態で すが、message1 は layopt タグ 等で visible=true としないと表示されないので注意してください。

パラメータ必須解説
layer × 操作対象のメッセージレイヤを指定します。指定がない場合、現在のメッセージレイヤとみなされます
page × 表画面を対象とするか、裏画面を対象とするかを指定します。省略すると表ページとみなされます
  • サンプルコード

[current layer="message0"]
message0レイヤに表示されています[l]
[current layer="message1"]
message1レイヤに表示されています[l]

[position]　メッセージレイヤの属性変更

  • レイヤ関連

メッセージレイヤに対する様々な属性を指定します。<br />
いずれの属性も、省略すれば設定は変更されません。

パラメータ必須解説
layer × 対象とするメッセージレイヤを指定します。
省略するとcurrentタグで指定されたレイヤが選択されます
page × 対象とするページを指定します。"fore"か"back"を指定して下さい。
この属性を省略するとcurrentタグで指定された、現在のページが選択されます。
left × メッセージレイヤの左端位置を指定します。（ピクセル）
top × メッセージレイヤの上端位置を指定します。（ピクセル）
width × メッセージレイヤの幅を指定します。（ピクセル）
height × メッセージレイヤの高さを指定します。（ピクセル）
frame × メッセージレイヤのフレーム画像として表示させる画像を指定します。
メッセージエリアをカスタマイズしたい場合に利用できます。
画像サイズはwidthとheight属性に準じて調整して下さい。
さらに、margin属性で実際にメッセージが表示される箇所の調整も行いましょう
また、"none"と指定することで標準枠に戻すこともできます。違う枠画像をしていすると切り替えることもできます
color × メッセージレイヤの表示色を 0xRRGGBB 形式で指定 します。
opacity × メッセージレイヤの不透明度を 0 ～ 255 の数値で指定しま す(文字の不透明度や、レイヤ自体の不透明度ではありません)。0 で完全 に透明です。
marginl × メッセージレイヤの左余白を指定します。
margint × メッセージレイヤの上余白を指定します。
marginr × メッセージレイヤの右余白を指定します。
marginb × メッセージレイヤの下余白を指定します。
vertical × メッセージレイヤを縦書きにモードにするには "true" を指定します。 横書きにするには "false" を指定してください。
visible × true に設定すると、メッセージレイヤが可視(表示状態)になります。
false に設定すると、メッセージレイヤは不可視(非表示状態)になります。
  • サンプルコード

;メッセージレイヤの位置とサイズを変更
[position width=400 height=300 top=100 left=20]
;メッセージレイヤの色と透明度を変更
[position color=blue opacity=100]

[image]　画像を表示

  • レイヤ関連

レイヤに画像を表示します。キャラクター表示や背景切り替えなどに使用できます。前景レイヤは初期状態では非表示なのでvisible=trueとすることで表示されます

パラメータ必須解説
storage × 画像ファイル名を指定します。ファイルは背景レイヤならプロジェクトフォルダのbgimage、前景レイヤならfgimageに入れてください
layer × 対象とするメレイヤを指定します。
"base"を指定すると背景レイヤ。0以上の整数を指定すると対応する前景レイヤに画像を表示します
page × 対象とするページを指定します。"fore"か"back"を指定して下さい。
この属性を省略すると"fore"であるとみなされます
visible × true or false を指定。imageは通常、非表示で始まるが、trueを指定すると最初から表示状態にできる。
left × 画像の左端位置を指定します。（ピクセル）
top × 画像の上端位置を指定します。（ピクセル）
x × 画像の左端位置を指定します。leftと同様。こちらが優先度高（ピクセル）
y × 画像の上端位置を指定します。topと同様。こちらが優先度高（ピクセル）
width × 画像の横幅を指定します。（ピクセル）
height × 画像の高さ位置を指定します。（ピクセル）
folder × 好きな画像フォルダから、画像を選択できます。通常前景レイヤはfgimage　背景レイヤはbgimageと決まっていますが、ここで記述したフォルダ以下の画像ファイルを使用することができるようになります。
name × ティラノスクリプトのみ。animタグなどからこの名前でアニメーションさせることができます。でまた名前を指定しておくとクラス属性としてJSから操作できます。カンマで区切ることで複数指定することもできます
time × ミリ秒を指定することで、徐々にイメージを表示させることができます。
wait × falseを指定すると、画像が表示されるのを待たずに、処理を進め明日。デフォルトはtrue
zindex × 画像同士の重なりを指定できます。数値が大きい方が前に表示されます
pos × レイヤ位置を自動的に決定します。前景レイヤに対して使います。横方向の位置は、この属性で指定した left ( 左端 ) 、left_center ( 左より )、center ( 中央 )、 right_center ( 右より )、right ( 右端 ) の位置に表示されます。各横方向の座標の中心 位置は Config.tjs で指定することができます。
left 、left_center、 center、 right_center、 right の代わりに、それぞれ l、 lc、 c、 rc、 r を 指定することもできます ( 動作は同じです )。
この属性を指定した場合は left 属性や top 属性は無視されます。
layerをbase と指定した場合にはこの属性は指定しないでください。各々の表示位置はConfig.tjsで事前に設定しておきましょう
  • サンプルコード

;背景変更をトランジションで実施
@layopt layer=message0 visible=false
[backlay]
[image layer=base page=back storage=rouka.jpg]
[trans time=2000]
[wt]
@layopt layer=message0 visible=true

[freeimage]　レイヤの解放

  • レイヤ関連


レイヤに追加された要素をすべて削除します　レイヤ指定は必須です。

パラメータ必須解説
layer ◯ 操作対象のレイヤを指定します。指定がない場合、現在のメッセージレイヤとみなされます
page × 表画面を対象とするか、裏画面を対象とするかを指定します。省略すると表ページとみなされます
time × ミリ秒を指定した場合、指定時間をかけてイメージが消えていきます
wait × 完了を待つかどうかを指定できます。trueを指定すると完了を待ちます。デフォルトはtrue
  • サンプルコード

[backlay]
;キャラクター表示
[image layer=0 page=back visible=true top=100 left=300 storage = chara.png]
[trans time=2000]
@wt

@backlay
;キャラクター非表示
[freeimage layer=0 page=back]
@trans time=2000
[wt]

[free]　オブジェクトの解放

  • レイヤ関連

レイヤに追加されたnameで指定された要素をすべて削除します　name指定は必須です。

パラメータ必須解説
layer ◯ 操作対象のレイヤを指定します。
name ◯ 削除する要素のnameを指定します。レイヤの中のあらゆるオブジェクトに適応できます。
time × ミリ秒を指定した場合、指定時間をかけてイメージが消えていきます
wait × 削除の完了を待つかどうかを指定できます。trueを指定すると完了を待ちます。デフォルトはtrue
  • サンプルコード

[backlay]
;キャラクター表示
[image name="myimage" layer=0 page=back visible=true top=100 left=300 storage = chara.png]
[trans time=2000]
@wt

;キャラクター非表示
[free layer=0 name="myimage"]


[ptext]　レイヤにテキストを追加

  • レイヤ関連

レイヤにテキストを表示します。前景レイヤに対してのみ実行します<br />
前景レイヤの属性を全て継承します。文字を消す時はfreeimageタグをレイヤに対して適応します
また、前景レイヤはデフォルト非表示なので、トランジションで表示しない場合はレイヤを可視状態にしてから、追加します。
[layopt layer=0 visible=true]が必要

パラメータ必須解説
layer ◯ 対象とするメレイヤを指定します。0以上の整数を指定すると対応する前景レイヤに画像を表示します
page × 対象とするページを指定します。"fore"か"back"を指定して下さい。
この属性を省略すると"fore"であるとみなされます
text × 表示するテキストの内容
x ◯ テキストの左端位置を指定します。（ピクセル）
y ◯ テキストの上端位置を指定します。（ピクセル）
vertical × true 、false のいずれかを指定してください。trueで縦書き表示されます。デフォルトは横書き
size × フォントサイズをピクセルで指定してください
face × フォントの種類を指定してください。非KAG互換ですが、ウェブフォントも使用できます
color × フォントの色を指定します
bold × 太字指定 boldと指定してください　HTML５互換ならfont-style指定に変換できます
edge × 文字の縁取りを有効にできます。縁取りする文字色を 0xRRGGBB 形式で指定します。
shadow × 文字に影をつけます。影の色を 0xRRGGBB 形式で指定します。縁取りをしている場合は無効化されます。
name × ティラノスクリプトのみ。animタグなどからこの名前でアニメーションさせることができます。でまた名前を指定しておくとクラス属性としてJSから操作できます。カンマで区切ることで複数指定することもできます
width × テキスト表示部分の横幅をピクセルで指定します
align × 文字の横方向に関する位置を指定できます。left（左寄せ）center（中央寄せ）right（右寄せ）デフォルトはleftです。widthパラメータで横幅を指定するのを忘れないようにしてください
time × ミリ秒を指定します。指定した時間をかけて徐々に表示させることができます
overwrite × true か false を指定します。同時にnameを指定している場合既に存在するptextの内容を変更できます。デフォルトはfalse
  • サンプルコード

[backlay]
[ptext page=back text="テキストテキスト" size=30 x=200 y=300 color=red vertical=true]
[trans time=2000]
[wt]
[l]
表示したテキストを消去します
[freeimage layer = 0]

[mtext]　演出テキスト

  • レイヤ関連

多彩な演出効果をもったテキストを画面上に表示します。
指定できる演出アニメーションは http://tyrano.jp/mtext/ を参照

[layopt layer=0 visible=true]が必要です。

パラメータ必須解説
layer × 対象とするレイヤを指定します。0以上の整数を指定すると対応する前景レイヤに画像を表示します
page × 対象とするページを指定します。"fore"か"back"を指定して下さい。
この属性を省略すると"fore"であるとみなされます
text × 表示するテキストの内容
x ◯ テキストの左端位置を指定します。（ピクセル）
y ◯ テキストの上端位置を指定します。（ピクセル）
vertical × true 、false のいずれかを指定してください。trueで縦書き表示されます。デフォルトは横書き
size × フォントサイズをピクセルで指定してください
face × フォントの種類を指定してください。非KAG互換ですが、ウェブフォントも使用できます
color × フォントの色を指定します
width × テキスト表示部分の横幅をピクセルで指定します
align × 文字の横方向に関する位置を指定できます。left（左寄せ）center（中央寄せ）right（右寄せ）デフォルトはleftです。widthパラメータで横幅を指定するのを忘れないようにしてください
name × ティラノスクリプトのみ。animタグなどからこの名前でアニメーションさせることができます。でまた名前を指定しておくとクラス属性としてJSから操作できます。カンマで区切ることで複数指定することもできます
bold × 太字指定 boldと指定してください　HTML５互換ならfont-style指定に変換できます
edge × 文字の縁取りを有効にできます。縁取りする文字色を 0xRRGGBB 形式で指定します
shadow × 文字に影をつけます。影の色を 0xRRGGBB 形式で指定します。縁取りをしている場合は無効化されます。
fadeout × テキスト表示後にフェードアウトを実行するか否かをtrue false で指定します。デフォルトはtrueです。残った文字を消す場合はfreeimageタグを使ってlayerを消して下さい
time × テキストが静止している時間をミリ秒で指定します。
wait × trueかfalse を指定します。trueを指定すると、テキストの演出完了を待ちます。デフォルトはtrue
in_effect × 文字が表示される際のアニメーション演出を指定します。
in_delay × 文字が表示される際の速度を指定します。何秒遅れて１文字が表示されるかをミリ秒で指定します。デフォルトは50です
in_delay_scale × １文字にかかるアニメーションの比率を指定します。デフォルトは1.5
in_sync × trueを指定すると、すべての文字が同時にアニメーションを開始します。デフォルトはfalse
in_shuffle × trueを指定すると、文字アニメーションのタイミングがランダムに実行されます。デフォルトはfalse
in_reverse × trueを指定すると、文字が後ろから表示されていきます。デフォルトはfalse"
out_effect × 文字が消える際のアニメーション演出を指定します。指定できるアニメーションは
out_delay × 文字が消える際の速度を指定します。何秒遅れて１文字が消えるかをミリ秒で指定します。デフォルトは50です
out_delay_scale × １文字にかかるアニメーションの比率を指定します。デフォルトは1.5
out_sync × trueを指定すると、すべての文字が同時にアニメーションを開始します。デフォルトはfalse
out_shuffle × trueを指定すると、文字アニメーションのタイミングがランダムに実行されます。デフォルトはfalse
out_reverse × trueを指定すると、文字が後ろから消えていきます。デフォルトはfalse"
  • サンプルコード

;デフォルトは前景レイヤは配置されますので表示状態にしておく
[layopt layer=0 visible=true]
[mtext text="演出テキスト" x=100 y=100 in_effect="fadeIn" out_effect="fadeOut"]

[backlay]　レイヤ情報の表ページから裏ページへのコピー

  • レイヤ関連

指定したレイヤ、あるいはすべてのレイヤの情報を、表ページから裏ページに コピーします。
利用方法としてはtrans タグで表ページのレイヤの画像を裏ページの レイヤの画像に置き換えます。
そのため、トランジション前にこの backlay タ グで画像を裏ページに転送し、裏ページでレイヤを操作してから、トランジションを 行うという方法に用います。

パラメータ必須解説
layer × 対象となるレイヤを指定します。
base を指定すると 背景レイヤ になります。
0 以上の整数を指定すると前景レイヤになります。
message0 または message1 を指定するとメッセージレイヤにな ります。
単に message とのみ指定した場合は、 current タグで指定した現在の操作対象のメッセージレイヤが 対象になります ( 裏ページのメッセージレイヤが操作対象であっても そのメッセージレイヤの表ページ→裏ページへのコピーが行われます )。
省略すると、すべてのレイヤの情報が裏ページにコピーされます。
  • サンプルコード

;背景変更をトランジションで実施
@layopt layer=message0 visible=false
[backlay]
[image layer=base page=back storage=rouka.jpg]
[trans time=2000]
[wt]

[wt]　トランジションの終了待ち

  • レイヤ関連

トランジションが終了するまで、待ちます。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[backlay]
[image layer=base page=back storage=rouka.jpg]
[trans time=2000]
;トランジションが終わるまで先へ進まない
[wt]

[link]　ハイパーリンク（選択肢）

  • ラベル・ジャンプ操作


link タグと endlink タグで囲まれた部分の文章を、 マウスやキーボードで選択可能にし、そこでクリックされたりキーを押されたときに、 ジャンプする先を指定できます。
また、囲まれた文章はページをまたぐことは出来ません(行をまたぐことはできます)。

パラメータ必須解説
storage × ジャンプ先のシナリオファイルを指定します。省略すると、現在 のシナリオファイル内であると見なされます
target × ジャンプ先のラベルを指定します。省略すると、ファイルの先頭から実行されます。
  • サンプルコード

選択肢を表示します[l][r][r]

[link target=*select1]【１】選択肢　その１[endlink][r]
[link target=*select2]【２】選択肢　その２[endlink][r]

[s]

*select1
[cm]
「選択肢１」がクリックされました[l]
@jump target=*common

*select2
[cm]
「選択肢２」がクリックされました[l]
@jump target=*common

*common
[cm]

共通ルートです

[endlink]　ハイパーリンク（選択肢）の終了を示します

  • ラベル・ジャンプ操作

ハイパーリンク（選択肢）の終了を示します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[link target=*select1]【１】選択肢　その１[endlink][r]
[link target=*select2]【２】選択肢　その２[endlink][r]

[s]　ゲームを停止する

  • システム操作

シナリオファイルの実行を停止します。
linkタグで選択肢表示した直後などに配置して利用する方法があります。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[link target=*select1]【１】選択肢　その１[endlink][r]
[link target=*select2]【２】選択肢　その２[endlink][r]
[s]

[wait]　ウェイトを入れる

  • システム操作

ウェイトを入れます。time属性で指定した時間、操作できなくなります。

パラメータ必須解説
time ◯ ウェイトをミリ秒で指定します。
  • サンプルコード

;2000ミリ秒（２秒）処理を停止します
[wait time=2000]

[wait_cancel]　ウェイトをキャンセルする

  • システム操作

[wait]タグで待ち状態のスタックが存在する場合、キャンセルできます。
これは[wait]中にボタンクリックなどでジャンプした先でキャンセルするような使い方をします。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード


[hidemessage]　メッセージを消す

  • レイヤ関連

メッセージレイヤを一時的に隠します。メニューから「メッセージを消す」を選んだのと 同じ動作を行います。
クリック待ちを行った後、メッセージレイヤは表示され、 実行は継続します。

パラメータ必須解説
指定できるパラメータはありません

[quake]　画面を揺らす

  • システム操作

指定したミリ秒だけ、画面を揺らします。（KAGの文字数指定は未対応）
vmax 属性を 0 に設定すると横揺れになります。hmax 属性を 0 に設定すると縦揺れになります。

パラメータ必須解説
count × 指定した回数揺らします
wait × trueかfalseを指定します。trueの場合は揺れが完了するまで、ゲームを停止します。デフォルトはtrue
time ◯ １回揺れるのにかかる時間をミリ秒で指定します。デフォルトは300
hmax × 揺れの横方向への最大振幅を指定します。省略すると 10(px) が指定されたと見なされます。
vmax × 揺れの縦方向への最大振幅を指定します。省略すると 10(px) が指定されたと見なされます。
  • サンプルコード

[quake count=5 time=300 hmax=20]

[font]　フォント属性設定

  • システム操作

文字の様々な属性を指定します。
これらの属性は、メッセージレイヤごとに個別に設定できます。
いずれの属性も、省略すると前の状態を引き継ぎます。また、default を指定すると Config.tjs 内で指定したデフォルトの値に戻ります。
resetfont や　ct cm er タグが実行されると、、Config.tjs 内や deffont タグで指定し たデフォルトの値に戻ります。

パラメータ必須解説
size × 文字サイズを指定します
color × 文字色を文字色を 0xRRGGBB 形式で指定します。（吉里吉里対応）　HTML5に限るならその他指定でも大丈夫です
bold × 太字指定。true 又は　false で指定
italic × trueを指定すると、イタリック体になります。デフォルトはfalseです
face × フォントの種類を指定。非KAG互換でウェブフォントも利用可能。プロジェクトフォルダのothersフォルダに配置してください。そして、tyrano.cssの@font-faceを指定することで利用できます。
edge × 文字の縁取りを有効にできます。縁取りする文字色を 0xRRGGBB 形式で指定します。縁取りを解除する場合は「none」と指定してください
shadow × 文字に影をつけます。影の色を 0xRRGGBB 形式で指定します。影を解除する場合は「none」と指定してください
  • サンプルコード

[font size=40 bold=true]
この文字は大きく、そして太字で表示されます。
[resetfont]
もとの大きさに戻りました。

[deffont]　デフォルトの文字属性設定

  • システム操作

現在操作対象のメッセージレイヤに対する、デフォルトの文字属性を指定します。
ここで指定した属性は、resetfont タグで実際に反映されます。
つまり、このタグを実行しただけではすぐにはフォントの属性は反映されません。resetfont タグ を実行する必要があります。

パラメータ必須解説
size × 文字サイズを指定します
color × 文字色を文字色を 0xRRGGBB 形式で指定します。（吉里吉里対応）　HTML5に限るならその他指定でも大丈夫です
bold × 太字指定。true 又は　false で指定
italic × trueを指定するとイタリック体で表示されます。デフォルトはface
edge × 文字の縁取りを有効にできます。縁取りする文字色を 0xRRGGBB 形式で指定します。縁取りを解除する場合は「none」と指定してください
shadow × 文字に影をつけます。影の色を 0xRRGGBB 形式で指定します。影を解除する場合は「none」と指定してください

[delay]　文字の表示速度の設定

  • システム操作

文字の表示速度を指定します。
文字表示をノーウェイトにするには nowait タグをつかう こともできます。

パラメータ必須解説
speed × 文字の表示速度を指定します

[resetdelay]　文字の表示速度をデフォルトに戻す

  • システム操作

文字の表示速度をデフォルト速度に戻します

パラメータ必須解説
指定できるパラメータはありません

[configdelay]　デフォルトの文字の表示速度の設定

  • システム操作

デフォルトの文字の表示速度を指定します。
つまり、resetdelay時にはこの速度が指定されます。
コンフィグ画面などで文字速度を指定する場合はこのタグをつかって指定します。

パラメータ必須解説
speed × 文字の表示速度を指定します

[nowait]　文字表示の瞬間表示

  • システム操作

待ち時間なしに、テキストを配置します。

パラメータ必須解説
指定できるパラメータはありません

[endnowait]　テキストの瞬間表示を取り消します。

  • システム操作

テキストメッセージは前回nowaitタグを指定した時のスピードへ戻ります

パラメータ必須解説
指定できるパラメータはありません

[resetfont]　フォント属性を元に戻す

  • システム操作

font タグで指定した文字の属性をデフォルトに戻します。
文字属性は、メッセージレイヤごとに個別に設定できます

パラメータ必須解説
指定できるパラメータはありません

[layopt]　レイヤの属性設定

  • レイヤ関連

レイヤの属性を指定します。

パラメータ必須解説
layer ◯ 対象となる前景レイヤまたはメッセージレイヤを指定します。 　message とのみ指定した場合は、current タグで指定した、現在の操作対象のメッセージレイヤが対象となります。
page × 表(fore)画面のレイヤを対象とするか、裏(back)画面のレイヤを対象と するかを指定します。省略すると表ページであると見なされます。ただしlayerをmessage とのみ指定した場合でこの属性を省略した場合は 現在操作対象のページのメッセージレイヤが選択されます。
visible × layer 属性で指定したレイヤを表示するか、しないかを指定 します。visibleをtrue と 指定すれば、レイヤは表示状態になります。visible
left × layer 属性で指定したレイヤの左端位置を指定します。 省略すると位置は変更しません。　layer 属性に message0 や message1 を指定した場合は、position タグで位置等を指定してください。
top × layer 属性で指定したレイヤの上端位置を指定します。 省略すると位置は変更しません。　layer 属性に message0 や message1 を指定した場合は、むしろ position タグで位置等を指定してください。
opacity × レイヤの不透明度を指定します。０～２５５の範囲で指定してください（２５５で全くの不透明）
  • サンプルコード

;メッセージレイヤを消去
@layopt layer=message0 visible=false
[backlay]
[image layer=0 page=back visible=true top=100 left=50 storage = miku1.png]
[trans time=2000]
@wt
;そしてレイヤ表示
@layopt layer=message0 visible=true

[ruby]　ルビを振る

  • メッセージ関連

次の一文字に対するルビを指定します。
ルビを表示させたい場合は毎回指定してください。
複数の文字にルビを振る場合は、一文字毎にルビを指定する必要があります。

パラメータ必須解説
text ◯ ルビとして表示させる文字を指定します
  • サンプルコード

[ruby text="かん"]漢[ruby text="じ"]字

[cancelskip]　スキップ解除

  • システム操作

スキップ状態の解除を行います。
プレイヤーにスキップ状態の停止を強制させることができます

パラメータ必須解説
指定できるパラメータはありません

[locate]　表示位置の指定

  • システム操作

グラフィックボタンの表示位置を指定します。
テキストには対応しておりません。

パラメータ必須解説
x × 横方向位置指定
y × 縦方向位置指定
  • サンプルコード

[locate x=20 y=100]
[button graphic="oda.png" target=*oda]

[locate x=300 y=100]
[button graphic="toyo.png" target=*toyo]


[button]　グラフィカルボタンの表示

  • ラベル・ジャンプ操作

グラフィカルボタンを表示します。
linkタグの画像版となります。
ただし、グラフィックボタン表示中は強制的にシナリオ進行が停止しますので、必ずジャンプ先を指定して下さい
また、グラフィックボタンの表示位置は直前のlocateタグによる指定位置を参照します。
ただし、x、y が指定されている場合は、そちらが優先されます。
ここから、移動した場合はコールスタックに残りません。つまり、リターンできないのでご注意ください
注意→fixにtrueを指定した場合はコールスタックに残ります。コール先からリターンするまで全てのボタンは有効にならないのでご注意ください
ジャンプ後に必ず[cm]タグでボタンを非表示にする必要があります。

パラメータ必須解説
graphic × ボタンにする画像を指定します。ファイルはプロジェクトフォルダのimageフォルダに入れて下さい
storage × ジャンプ先のシナリオファイルを指定します。省略すると、現在 のシナリオファイル内であると見なされます。
target × ジャンプ先のラベルを指定します。省略すると、ファイルの先頭から実行されます。
name × ティラノスクリプトのみ。animタグなどからこの名前でアニメーションさせることができます。でまた名前を指定しておくとクラス属性としてJSから操作できます。カンマで区切ることで複数指定することもできます
x × ボタンの横位置を指定します
y × ボタンの縦位置を指定します。
width × ボタンの横幅をピクセルで指定できます
height × ボタンの高さをピクセルで指定できます
fix × true falseで指定します。デフォルトはfalse 。trueを指定すると、Fixレイヤーにボタンが配置されます。この場合、ボタンを表示してもシナリオを進める事ができます。例えば、セーブボタンといった常に表示したいボタンを配置する時に活用できます。また、fixレイヤーに追加した要素を消す場合はclearfixタグ を使います。fixをtrueの場合は必ず別storageのtargetを指定してその場所にボタンが押されたときの処理を記述します。fixをtrueにした場合コールスタックが残ります。コールスタックが消化されるまではボタンが有効にならないのでご注意ください。
savesnap × true or false で指定します。デフォルトはfalse このボタンが押された時点でのセーブスナップを確保します。セーブ画面へ移動する場合はここをtrueにして、保存してからセーブを実行します
folder × 好きな画像フォルダから、画像を選択できます。通常前景レイヤはfgimage　背景レイヤはbgimageと決まっていますが、ここで記述したフォルダ以下の画像ファイルを使用することができるようになります。
exp × ボタンがクリックされた時に実行されるJSを指定できます。
preexp × "タグが評価された時点で変数 preexpに値を格納します。つまり、ボタンがクリックされた時に、expでpreexpという変数が利用できます。"
hint × マウスカーソルを静止させたときに表示されるツールチップの文字列を指定できます。
clickse × ボタンをクリックした時に再生される効果音を設定できます。効果音ファイルはsoundフォルダに配置してください
enterse × ボタンの上にマウスカーソルが乗った時に再生する効果音を設定できます。効果音ファイルはsoundフォルダに配置してください
leavese × ボタンの上からマウスカーソルが外れた時に再生する効果音を設定できます。効果音ファイルはsoundフォルダに配置してください。
clickimg × ボタンをクリックした時に切り替える画像ファイルを指定できます。ファイルはimageフォルダに配置してください
enterimg × ボタンの上にマウスカーソルが乗った時に切り替える画像ファイルを指定できます。ファイルはimageフォルダに配置してください。
visible × 初期状態で表示か非表示を選択できます。trueで表示falseで非表示の初期状態となります
auto_next × true or false を指定します。falseを指定すると、fixの場合、[return]で戻った時に次のタグへ進ませません。
role × ボタンに特別な機能を割り当てることができます。この場合storageやtargetは無視されます。強制的にfix属性がtrueになります。指定できる文字列はsave(セーブ画面を表示します)。load(ロード画面を表示します)。title(タイトル画面に戻ります)。menu(メニュー画面を表示します)。window(メッセージウィンドウを非表示にします)。skip(スキップの実行)。backlog（過去ログを表示）。fullscreen(フルスクリーン切り替え)。quicksave(クイックセーブ実行)。quickload(クイックロード実行)。auto（オート開始）。sleepgame（ゲームの状態を保存してジャンプ）
  • サンプルコード

[locate x=20 y=100]
[button graphic="oda.png" target=*oda]

[locate x=300 y=100]
[button graphic="toyo.png" target=*toyo]


[glink]　グラフィカルリンク

  • ラベル・ジャンプ操作

グラフィカルなボタンを表示することができます。画像は必要ありません
グラフィックリンク表示中は強制的にシナリオ進行が停止しますので、必ずジャンプ先を指定して下さい
また、グラフィックボタンの表示位置は直前のlocateタグによる指定位置を参照します。
ただし、x、y が指定されている場合は、そちらが優先されます。
ここから、移動した場合はコールスタックに残りません。つまり、リターンできないのでご注意ください
ジャンプ後は自動的に[cm]タグが実行され、ボタンは消失します

パラメータ必須解説
color × ボタンの色を指定できます。デフォルトはblackです（black gray white orange red blue rosy green pink）
font_color × フォントの色を指定できます。0xRRGGBB 形式で指定してください。
storage × ジャンプ先のシナリオファイルを指定します。省略すると、現在 のシナリオファイル内であると見なされます。
target × ジャンプ先のラベルを指定します。省略すると、ファイルの先頭から実行されます。
name × ティラノスクリプトのみ。animタグなどからこの名前でアニメーションさせることができます。でまた名前を指定しておくとクラス属性としてJSから操作できます。カンマで区切ることで複数指定することもできます
text × ボタンの文字列です
font_color × フォントの色を指定できます
x × ボタンの横位置を指定します
y × ボタンの縦位置を指定します。
width × ボタンの横幅をピクセルで指定できます
height × ボタンの高さをピクセルで指定できます
preexp × "タグが評価された時点で変数 preexpに値を格納します。つまり、ボタンがクリックされた時に、expでpreexpという変数が利用できます。"
exp × ボタンがクリックされた時に実行されるJSを指定できます。
size × フォントサイズを指定できます。デフォルトは３０です
face × フォントを指定できます。Webフォントを追加したい場合はfont.cssに定義を記述して下さい
graphic × ボタンの背景画像を指定します。ファイルはプロジェクトフォルダのimageフォルダに入れて下さい。画像が指定された場合はcolorは無視されます
enterimg × graphicが指定されている時に有効。カーソルが重なった時の画像を指定できます
clickse × ボタンをクリックした時に再生される効果音を設定できます。効果音ファイルはsoundフォルダに配置してください
enterse × ボタンの上にマウスカーソルが乗った時に再生する効果音を設定できます。効果音ファイルはsoundフォルダに配置してください
leavese × ボタンの上からマウスカーソルが外れた時に再生する効果音を設定できます。効果音ファイルはsoundフォルダに配置してください。
  • サンプルコード


[glink target="j1" text="選択肢１" size=20 width="500" y=300]
[glink target="j2" text="選択肢２" size=30 width="500" y=400]
[glink target="j3" text="選択肢３" size=30 width="500" y=400]

[s]


[clickable]　クリック可能な領域を設定

  • ラベル・ジャンプ操作

透明なクリック可能領域を設定することができます。
クリッカブルエリアの表示中は強制的にシナリオ進行が停止しますので、必ずジャンプ先を指定して下さい
また、グラフィックボタンの表示位置は直前のlocateタグによる指定位置を参照します
ここから、移動した場合はコールスタックに残りません。つまり、リターンできないのでご注意ください
☆重要：[s]タグに到達していない間は、クリッカブルは有効になりません。かならず、[s]タグでゲームを停止してください。

パラメータ必須解説
width ◯ 領域の横幅を指定します
height ◯ 領域に高さを指定します
x × 領域の左端位置のX座標を指定します
y × 領域の左端位置のY座標を指定します。
borderstyle × 領域に線を表示することができます。「線の太さ:線の種類（CSS準拠）:線の色」のフォーマットで記述して下さい。線の種類はsolid double groove dashed dotted などが指定できます
color × 表示色を 0xRRGGBB 形式で指定 します。
opacity × 領域の不透明度を 0 ～ 255 の数値で指定します0で完全 に透明です。
mouseopacity × 領域にマウスが乗った時透明度を変更することができます。領域の不透明度を 0 ～ 255 の数値で指定します0で完全 に透明です
storage × クリックされた際のジャンプ先のシナリオファイルを指定します。省略すると、現在 のシナリオファイル内であると見なされます。
target × クリックされた際のジャンプ先のラベルを指定します。省略すると、ファイルの先頭から実行されます。
  • サンプルコード

[locate x=20 y=100]
[clickable width=200 height=300 target=*oda]

[locate x=300 y=100]
[clickable width=100 height=100 border="solid:1px:gray" target=*oda]

[s]


[glyph]　クリック待ち記号の指定

  • システム操作

クリック待ち記号を表示する位置を設定できます
クリック記号はプロジェクトフォルダのtyrano/images/system/nextpage.gifを変更することで対応します

パラメータ必須解説
line × クリック待ちの表示画像を指定することができます。tyrano/images/system/nextpage.gifと同一のフォルダに配置してください
fix × trueを指定すると、left、及び、topを指定した位置に表示されます。
left × fix 属性を true にしたときに記号を表示する位置のうち、左端位置を 指定します
top × fix 属性を true にしたときに記号を表示する位置のうち、上端位置を 指定します
  • サンプルコード

[glyph fix=true left=200 top=100 ]


[trans]　レイヤのトランジション

  • レイヤ関連

指定したレイヤでトランジションを行います。
トランジションは、常に裏ページの対象のレイヤが、表ページの対象のレイヤに 入れ替わる方向で行われます。
トランジション後は、表ページの対象のレイヤの画像、位置、サイズ、可視・不可視 の状態は裏ページの対象のレイヤと同じになります。
また、トランジション中はレイヤの属性変更などは行わないで下さい

パラメータ必須解説
layer ◯ 対象となるレイヤを指定します。
base を指定すると 背景レイヤ になります。
0 以上の整数を指定すると前景レイヤになります。
message0 または message1 を指定するとメッセージレイヤにな ります。
単に message とのみ指定した場合は、 current タグで指定した現在の操作対象のメッセージレイヤが 対象になります

通常は背景の変更などに使用されます。
children × 【廃止】falseの場合、layerで指定した場所だけtrans します。デフォルトはfalseです
time ◯ トランジションを行っている時間をミリ秒で指定します。
method × 切り替えのタイプを指定します。デフォルトは"fadeIn"です。指定できる演出は次の通りです。（V450以降）fadeIn/fadeInDown/fadeInLeft/fadeInRight/fadeInUp/
lightSpeedIn/rotateIn/rotateInDownLeft/rotateInDownRight/rotateInUpLeft/
rotateInUpRight/zoomIn/zoomInDown/zoomInLeft/
zoomInRight/zoomInUp/slideInDown/slideInLeft/
slideInRight/slideInUp/bounceIn /bounceInDown/
bounceInLeft/bounceInRight/bounceInUp/rollIn(V450以前)指定できる効果は「crossfade」「explode」「slide」「blind」「bounce」「clip」「drop」「fold」「puff」「scale」「shake」「size」
  • サンプルコード

[backlay]
[image storage=fg0 layer=0 page=back]
[trans time=1500 ]
[wt]

[bg]　背景の切り替え

  • レイヤ関連

背景の切り替えを簡易的に実行できます。
常にforeのレイヤに対して切り替えが実行されます

パラメータ必須解説
storage ◯ 切り替えるための画像ファイルを指定します。ファイルはbgimage以下に配置してください
time × 時間をミリ秒で指定します。
wait × 背景の切り替えが完了するまで処理を待ちます
cross × true or false を指定します。デフォルトはfalse。trueを指定すると２つの画像が同じタイミングで透明になりながら入れ替わります。falseを指定すると、古い背景を残しながら上に重なる形で新しい背景を表示します。CG差分などで使用する場合はfalseが良いでしょう。
method × 切り替えのタイプを指定します。デフォルトは"fadeIn"です。指定できる演出は次の通りです。（V450以降）fadeIn/fadeInDown/fadeInLeft/fadeInRight/fadeInUp/
lightSpeedIn/rotateIn/rotateInDownLeft/rotateInDownRight/rotateInUpLeft/
rotateInUpRight/zoomIn/zoomInDown/zoomInLeft/
zoomInRight/zoomInUp/slideInDown/slideInLeft/slideInRight/
slideInUp/bounceIn /bounceInDown/bounceInLeft/
bounceInRight/bounceInUp/rollIn/vanishIn/puffIn(V450以前)指定できる効果は「crossfade」「explode」「slide」「blind」「bounce」「clip」「drop」「fold」「puff」「scale」「shake」「size」
  • サンプルコード

[bg storage=fg0.png time=1500 wait=true]

[bg2]　背景の切り替え

  • レイヤ関連

背景の切り替えを簡易的に実行できます。
常にforeのレイヤに対して切り替えが実行されます

パラメータ必須解説
name × animタグなどからこの名前でアニメーションさせることができます。また、名前を指定しておくとクラス属性としてJSから操作できます。カンマで区切ることで複数指定することもできます
storage ◯ 切り替えるための画像ファイルを指定します。ファイルはbgimage以下に配置してください
left × 画像の左端位置を指定します。デフォルトは０です（ピクセル）
top × 画像の上端位置を指定します。デフォルトは０です（ピクセル）
width × 画像の横幅を指定します。（ピクセル）指定しない場合はゲーム画面に一致するサイズが設定されます
height × 画像の高さ位置を指定します。（ピクセル）指定しない場合はゲーム画面に一致するサイズが設定されます
time × 時間をミリ秒で指定します。
wait × 背景の切り替えが完了するまで処理を待ちます
cross × true or false を指定します。デフォルトはfalse。trueを指定すると２つの画像が同じタイミングで透明になりながら入れ替わります。falseを指定すると、古い背景を残しながら上に重なる形で新しい背景を表示します。CG差分などで使用する場合はfalseが良いでしょう。
method × 切り替えのタイプを指定します。デフォルトは"fadeIn"です。指定できる演出は次の通りです。（V450以降）fadeIn/fadeInDown/fadeInLeft/fadeInRight/fadeInUp/
lightSpeedIn/rotateIn/rotateInDownLeft/rotateInDownRight/rotateInUpLeft/
rotateInUpRight/zoomIn/zoomInDown/zoomInLeft/
zoomInRight/zoomInUp/slideInDown/slideInLeft/slideInRight/
slideInUp/bounceIn /bounceInDown/bounceInLeft/
bounceInRight/bounceInUp/rollIn/vanishIn/puffIn(V450以前)指定できる効果は「crossfade」「explode」「slide」「blind」「bounce」「clip」「drop」「fold」「puff」「scale」「shake」「size」
  • サンプルコード

[bg storage=fg0.png time=1500 wait=true]

[layermode]　レイヤーモード

  • レイヤ関連

レイヤの合成を行うことができます。
PCゲーム環境での推奨機能です。
一部ブラウザIE,Edge では動作しませんのでご注意ください

パラメータ必須解説
name × レイヤ合成に名前をつけることができます。この名前はfree_layremovdeで特定の合成のみを消したい際に使用できます
graphic × 合成する画像ファイルを指定してください。ファイルはimageフォルダに配置しします
color × 合成に色を指定することができます0xFFFFFF形式で指定してください
mode × 合成方法を指定できます。デフォルトは「multiply」 次の効果が使えます→ multiply（乗算）screen（スクリーン）overlay（オーバーレイ）darken（暗く）lighten（明るく）color-dodge（覆い焼きカラー）color-burn（焼き込みカラー）hard-light（ハードライト）soft-light（ソフトライト）difference（差の絶対値）exclusion（除外）hue（色相）saturation（彩度）color（カラー）luminosity（輝度）
folder × graphicで指定する画像のフォルダを変更できます。例えばbgimageと指定することで、背景画像から取得することができます。
opacity × 不透明度を 0 ～ 255 の数値で指定します。0 で完全 に透明です。デフォルトは透明度指定なしです
time × 合成はフェードインで行われます。合成が完了する時間をミリ秒(１秒
wait × 合成の完了を待つか否かを指定できます。trueかfalseを指定してください。デフォルトはtrueです
  • サンプルコード

[layermode graphic=fg0.png time=1500 mode=overlay]

[layermode_movie]　レイヤーモード動画

  • レイヤ関連

ゲーム画面に動画を合成を行うことができます。
PCゲーム環境での推奨機能です。
一部ブラウザIE,Edge では動作しませんのでご注意ください
効果を打ち消す場合は[free_layermode]タグを使用します。
動画形式はogv webm mp4 などに対応します
提供するゲームによって対応するフォーマットが異なります。
PCゲーム形式の場合は webm形式を使ってください。 mp4 に対応しません。

パラメータ必須解説
name × レイヤ合成に名前をつけることができます。この名前はfree_layremovdeで特定の合成のみを消したい際に使用できます
video ◯ 合成する動画ファイルを指定してください。ファイルはvideoフォルダに配置しします
volume × 合成する動画の音ボリュームを指定します。0〜100で指定します。デフォルトは０の消音です
loop × 動画をループするか否かをtrueかfalseで指定します。デフォルトはtrueです。ループ指定した場合、free_layermodeを行うまで演出が残ります。
speed × 動画の再生スピードを指定できます。デフォルトは１ つまり2を指定すると２倍速、0.5を指定すると半分の速度で再生されます
mode × 合成方法を指定できます。デフォルトは「multiply」 次の効果が使えます→ multiply（乗算）screen（スクリーン）overlay（オーバーレイ）darken（暗く）lighten（明るく）color-dodge（覆い焼きカラー）color-burn（焼き込みカラー）hard-light（ハードライト）soft-light（ソフトライト）difference（差の絶対値）exclusion（除外）hue（色相）saturation（彩度）color（カラー）luminosity（輝度）
opacity × 不透明度を 0 ～ 255 の数値で指定します。0 で完全 に透明です。デフォルトは透明度指定なしです
time × 合成はフェードインで行われます。合成が完了する時間をミリ秒(１秒
wait × 動作効果の再生完了を待つか否かをtrueかfalseで指定できます。デフォルトはfalseです
  • サンプルコード

[layermode_movie video=test.webm time=1500 wait=true]

[free_layermode]　レイヤーモードの開放

  • レイヤ関連

レイヤの合成を取り消します

パラメータ必須解説
name × 名前を指定して合成を行っている場合、ここで特定の合成のみを削除することも可能です。指定しない場合はすべての効果が消されます
time × 合成はフェードアウトで消えていきます。フェードアウトにかかる時間をミリ秒で指定できます。デフォルトは500ミリ秒です
wait × フェードアウトの完了を待つか否かをtrueかfalseで指定できます。デフォルトはtrueです。
  • サンプルコード

[free_layermode name="test"]

[playbgm]　BGMの再生

  • オーディオ関連

BGMを再生します。
再生するファイルはプロジェクトフォルダのbgmフォルダに格納してください。

ogg形式、HTML5標準をサポートします。
動作させる環境によって対応フォーマットが異なります。

基本的にogg形式を指定しておけば問題ありません。
ただし、複数のブラウザ形式の場合、IEとSafariにも対応させるためには
bgmフォルダに同名でaac形式(m4a)ファイルも配置して下さい。
すると自動的に適切なファイルを選択して再生します。

デフォルト設定ではmp3は再生できません。
Confit.tjs の mediaFormatDefaultをmp3に変更して下さい。
ただしこの場合 PCアプリとしては動作しません

パラメータ必須解説
storage ◯ 再生する音楽ファイルを指定してください
loop × true（デフォルト）またはfalse を指定してください。trueを指定すると繰り返し再生されます。smoothを指定すると、ループが滑らかになります。
click × スマートフォンのブラウザから閲覧した場合のみ動作（アプリの場合不要）true またはfalse（デフォルト）を指定してください。trueの場合、スマートフォン（ブラウザ）から閲覧した場合、再生前にクリックが必要になります。これは、スマートフォンの仕様上、クリックしないと音が鳴らせない縛りがあるため、例えば、背景変更後に音楽再生をしたい場合はtrueを指定しないと音はなりません。通常のテキストの中で音楽再生の場合はfalseで大丈夫です。スマートフォンから閲覧して音楽が鳴らない場合はtrueにしてみてください
volume × 再生する音量を指定できます。0〜100 の範囲で指定して下さい。（デフォルトは100）
  • サンプルコード

[playbgm storage="music.ogg"]

[stopbgm]　BGMの停止

  • オーディオ関連

再生しているBGMの再生を停止します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[stopbgm ]

[fadeinbgm]　BGMにフェードイン

  • オーディオ関連

BGMを徐々に再生します。
一部環境（Firefox、Sarafi等）においては対応していません。その場合、playbgmの動作となります。

パラメータ必須解説
storage ◯ 再生する音楽ファイルを指定してください
loop × true（デフォルト）またはfalse を指定してください。trueを指定すると繰り返し再生されます
click × スマートフォンのブラウザから閲覧した場合のみ動作（アプリの場合不要）true またはfalse（デフォルト）を指定してください。trueの場合、スマートフォン（ブラウザ）から閲覧した場合、再生前にクリックが必要になります。これは、スマートフォンの仕様上、クリックしないと音が鳴らせない縛りがあるため、例えば、背景変更後に音楽再生をしたい場合はtrueを指定しないと音はなりません。通常のテキストの中で音楽再生の場合はfalseで大丈夫です。スマートフォンから閲覧して音楽が鳴らない場合はtrueにしてみてください
time ◯ フェードインを行なっている時間をミリ秒で指定します。
volume × BGMの再生音量を変更できます（0〜100）
  • サンプルコード

[fadeinbgm storage=sample.ogg loop=false time=3000]

[fadeoutbgm]　

  • オーディオ関連

再生中のBGMをフェードアウトしながら停止します。
一部環境（Firefox、Sarafi等）においては対応していません。その場合、stopbgmの動作となります。

パラメータ必須解説
time × フェードアウトを行なっている時間をミリ秒で指定します。
  • サンプルコード

[fadeoutbgm time=3000]

[xchgbgm]　【非推奨】BGMのクロスフェード（入れ替え）

  • オーディオ関連

【非推奨】BGMを入れ替えます。
音楽が交差して切り替わる演出に使用できます。
一部環境（Firefox、Safari等）において対応していません。その場合、playbgmの動作となります。

パラメータ必須解説
storage ◯ 次に再生するファイルを指定してください
loop × true（デフォルト）またはfalse を指定してください。trueを指定すると繰り返し再生されます
click × スマートフォンのブラウザから閲覧した場合のみ動作（アプリの場合不要）true またはfalse（デフォルト）を指定してください。trueの場合、スマートフォン（ブラウザ）から閲覧した場合、再生前にクリックが必要になります。これは、スマートフォンの仕様上、クリックしないと音が鳴らせない縛りがあるため、例えば、背景変更後に音楽再生をしたい場合はtrueを指定しないと音はなりません。通常のテキストの中で音楽再生の場合はfalseで大丈夫です。スマートフォンから閲覧して音楽が鳴らない場合はtrueにしてみてください
time ◯ クロスフェードを行なっている時間をミリ秒で指定します。
  • サンプルコード

[xchgbgm storage=new.ogg loop=true time=3000]

[playse]　効果音の再生

  • オーディオ関連

効果音を再生します
効果音ファイルはプロジェクトフォルダのsoundフォルダに入れてください

ogg形式、HTML5標準をサポートします。
動作させる環境によって対応フォーマットが異なります。

基本的にogg形式を指定しておけば問題ありません。
ただし、複数のブラウザ形式の場合、IEとSafariにも対応させるためには
bgmフォルダに同名でaac形式(m4a)ファイルも配置して下さい。
すると自動的に適切なファイルを選択して再生します。

デフォルト設定ではmp3は再生できません。
Confit.tjs の mediaFormatDefaultをmp3に変更して下さい。
ただしこの場合 PCアプリとしては動作しません

パラメータ必須解説
storage ◯ 再生するファイルを指定してください
buf × 効果音を再生するスロットを指定できます。デフォルトは0
click × スマホブラウザで効果音を鳴らす場合、クリック後でないと再生できません。スマホブラウザで音がならない場合trueを指定してみてください。デフォルトはfalse
loop × trueまたはfalse （デフォルト）を指定してください。trueを指定すると繰り返し再生されます
clear × trueまたはfalse(デフォルト) 他のSEが鳴っている場合、trueだと他のSEを停止した後、再生します。音声などはtrueが便利でしょう
volume × 効果音の再生音量を変更できます（0〜100）
  • サンプルコード

[playse storage=sound.ogg loop=false ]

[stopse]　効果音の停止

  • オーディオ関連

効果音を再生を停止します

パラメータ必須解説
buf × 効果音を停止するスロットを指定できます。デフォルトは0
  • サンプルコード

[stopse ]

[fadeinse]　効果音のフェードイン

  • オーディオ関連

です。stopse を使用して下さい
効果音をフェードインしながら再生します

パラメータ必須解説
storage ◯ 次に再生するファイルを指定してください
loop × trueまたはfalse （デフォルト）を指定してください。trueを指定すると繰り返し再生されます
buf × 効果音を停止するスロットを指定できます。デフォルトは0
time ◯ フェードインの時間をミリ秒で指定します
  • サンプルコード

[fadeinse storage=sound.ogg loop=false time=2000 ]

[fadeoutse]　効果音の停止

  • オーディオ関連

効果音をフェードアウトします

パラメータ必須解説
time × フェードアウトを行なっている時間をミリ秒で指定します。buf
指定できるパラメータはありません
  • サンプルコード

[fadeoutse time=2000 ]

[bgmopt]　BGM設定

  • オーディオ関連

BGMの設定を変更できます
音量設定については スマートフォンブラウザからの閲覧の場合、端末の制限により変更できません。

パラメータ必須解説
volume × BGMの再生音量を変更できます（0〜100）
effect × true false を指定して下さい（デフォルトはtrue） trueだと再生中のBGMに即反映します
buf × 設定を変更するスロットを指定できます。指定がない場合はすべてのスロットが対象になります
  • サンプルコード

[bgmopt volume=50 ]

[seopt]　SE設定

  • オーディオ関連

SEの設定を変更できます
音量設定については スマートフォンブラウザからの閲覧の場合、端末の制限により変更できません。

パラメータ必須解説
volume × SEの再生音量を変更できます（0〜100）
effect × true false を指定して下さい（デフォルトはtrue） trueだと再生中のBGMに即反映します
buf × 設定を変更するスロットを指定できます。指定がない場合はすべてのスロットが対象になります
  • サンプルコード

[seopt volume=50 ]

[wbgm]　BGMの再生完了を待つ

  • オーディオ関連

BGMの再生完了を待ちます。playbgmでループ再生している場合は永遠に止まりますのでご注意下さい。
このタグはPCゲーム、ブラウザゲームで利用できます。
スマホアプリでは利用できませんのでご注意ください。

パラメータ必須解説
指定できるパラメータはありません

[wse]　効果音の再生完了を待つ

  • オーディオ関連

効果音の再生完了を待ちます。
このタグはPCゲーム、ブラウザゲームで利用できます。
スマホアプリでは利用できませんのでご注意ください。

パラメータ必須解説
指定できるパラメータはありません

[voconfig]　ボイスの再生設定

  • オーディオ関連

ボイスを効率的に再生するための設定ができます。
キャラクター名と音声ファイル名を関連させておくことで
キャラ名表示のタイミングで音声ファイルを順番に再生させることができます。
このタグで設定をした後、[vostart]タグで自動再生を開始しないと有効になりません。

パラメータ必須解説
sebuf × ボイスで使用するplayseのbufを指定してください
name × ボイスを再生するキャラクター名を指定します。[chara_new ]タグのnameパラメータです
vostorage × 音声ファイルとして使用するファイル名のテンプレートを指定します。{number}の部分に再生されることに+1された数字が入っていきます
number × デフォルトは０。vostorageで適応する数字をここで指定した値にリセットできます
  • サンプルコード

[voconfig sebuf=2 name="akane" vostorage="akane_{number}.ogg" number=1 ]
[voconfig sebuf=2 name="yamato" vostorage="yamato_{number}.ogg" number=1 ]

;音声自動再生を開始する。必ず必要です。
[vostart]

#akane
ここで音声再生(akane_1.ogg)[p]

#akane
次の音声再生(akane_2.ogg)[p]

#yamato
やまとの音声再生(yamato_1.ogg)[p]

#akane
あかねの音声再生(akane_3.ogg)[p]


[vostart]　ボイス自動再生開始

  • オーディオ関連

voconfigで指定したボイスの自動再生を開始します。
コレ以降、#で名前を指定した場合、紐付いたボイスが再生されていきます。

パラメータ必須解説
指定できるパラメータはありません

[vostop]　ボイス自動再生停止

  • オーディオ関連

voconfigで指定したボイスの自動再生を停止します。
コレ以降、#で名前を指定しても、ボイスが紐付いて再生されることを防ぎます。

パラメータ必須解説
指定できるパラメータはありません

[eval]　式の評価

  • マクロ・変数・JS操作

expで示された式を評価します。変数への値の代入などに使用されます。
exp には任意の TJS(JS) 式を指定できるので、TJS(JS) として有効な式であれば 何でも評価できます。

パラメータ必須解説
exp ◯ 評価するTJS式を指定します。
  • サンプルコード

[eval exp="f.test=500"]
;↑ゲーム変数 test に数値を代入している
[eval exp="f.test2='文字列'"]
;↑ゲーム変数 test2 に文字列を代入している
[eval exp="sf.test=400"]
;↑システム変数 test に数値を代入している
[eval exp="f.test2=f.test*3"]
;↑ゲーム変数 test2 に ゲーム変数 test の 3 倍の数値を代入している

[clearvar]　ゲーム変数の全消去

  • マクロ・変数・JS操作

ゲーム変数をすべて消去します

パラメータ必須解説
指定できるパラメータはありません

[clearsysvar]　システム変数の全消去

  • マクロ・変数・JS操作

システム変数を全消去します

パラメータ必須解説
指定できるパラメータはありません

[clearstack]　スタックの消去

  • マクロ・変数・JS操作

システムが管理するスタックを消去します。
スタックとはゲームを進める中で Call、マクロ呼び出し、 if 文などを通過した時に
呼び出し元に帰ってくるために保持するメモリ領域です。
通常のノベルゲームであれば、特に問題はおきませんが
Call の途中でジャンプ。if文の中でジャンプ
などを繰り返した場合、回収されないスタックが溜まっていきます。
これらは、セーブデータの肥大化などを引き起こす場合ばあるので
戻るべきスタックが無い場面でこのタグを配置しておくことをオススメします。
きりの良い場所などです。（タイトル 章の始まり）

パラメータ必須解説
stack × call if macro のいづれかを指定できます。特定のスタックのみ削除することができます。指定しなければ全てのスタックを削除します。

[close]　ウィンドウを閉じる

  • システム操作

ウィンドウを閉じます。
ブラウザから閲覧している場合は、ブラウザが終了します

パラメータ必須解説
ask × true を指定すると、終了するかどうかの確認をします。false を 指定するとこの確認はありません。この属性を省略 すると、 true を指定したとみなされます。

[trace]　コンソールへの値の出力

  • その他

expで指定された式を評価し、結果をコンソールに出力します。
【KAG3吉里吉里の場合】
コンソールは Shift+F4 で表示されるほか、Config.tjs 内で logMode を設定することに より、ファイルに記録することもできます。
【ティラノスクリプト　ブラウザの場合】
ブラウザのウェブインスペクタからコンソールを確認してください

パラメータ必須解説
exp × 評価するTJS（JS）式を指定します
  • サンプルコード

[trace exp="f.test"]
; ↑ ゲーム変数 test の内容を コンソール に出力する

[title]　タイトル指定

  • システム操作

ゲームタイトルを指定します。
例えば、章ごとにタイトルを変えるとプレイヤーからわかりやすくなります。
吉里吉里の場合、アプリのウィンドウタイトル。
ティラノスクリプトの場合、ブラウザタイトルが変わります

パラメータ必須解説
name ◯ 表示したいタイトルを指定してください
  • サンプルコード

[title name="変更後のタイトル"]

[iscript]　JavaScriptの記述

  • マクロ・変数・JS操作

[iscript]と[endscript]に囲まれた箇所にJavaScriptを記述することができます。
TJSの式にも適応できますが、ティラノスクリプトとの動作互換はありません

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[iscript]

var test = 22;
f.name = test;
alert("javascriptの関数にもアクセス可能");
//jqueryも利用可能 コメントもJS方式利用可能
$("body").html();

[endscript]

[endscript]　JavaScriptの終了

  • マクロ・変数・JS操作

JavaScriptの記述を終了します

パラメータ必須解説
stop × endscriptに到達した時、ここにtrueを指定すると次のタグに進ませない。scriptの中でjumpした時などに指定する。デフォルトはfalse

[html]　HTMLをレイヤ追加

  • その他

[html]と[endhtml]の間に記述したHTMLを表示することができます。
この機能は非常に強力です。もちろんJavaScriptタグ。Canvasなど次世代Web表現を全てサポートします。
例えば、Youtubeのビデオプレイヤーを挿入したり、無数に公開されているWebAPIとの連携なども可能です。
このタグで挿入した場合は最前面にHTML要素が挿入されます
cmタグなどで画面をクリアしない限り、クリックしてもゲームが進みません。
必ずグラフィックボタンなども配置して、ジャンプでゲームを進める状態にしておくことが必要です。
タグの中に、ティラノスクリプトの変数を挿入することもできます。
従来通りHTMLの中で[emb]タグを使用してください

パラメータ必須解説
left × HTMLタグの左端位置を指定します。（ピクセル）
top × HTMLの上端位置を指定します。（ピクセル）
name × HTML領域に名前を指定することができます。この名前を使って、HTML領域に対してアニメーションなども実行できます。
  • サンプルコード


;youtubeのプレイヤーを指定した位置に挿入します
;yoububeから埋め込み用タグを取得してきています
[html top=100 left=300]

<object width="200" height="113">
<param name="movie" value="http://www.youtube.com/v/60TMm2sQTBU?version=3&amp;hl=ja_JP&amp;rel=0">
</param>
<param name="allowFullScreen" value="true"></param>
<param name="allowscriptaccess" value="always"></param>
<embed src="http://www.youtube.com/v/60TMm2sQTBU?version=3&amp;hl=ja_JP&amp;rel=0" type="application/x-shockwave-flash" width="200" height="113" allowscriptaccess="always" allowfullscreen="true">
</embed></object>

[endhtml]

[endhtml]　HTMLの終了

  • その他

HTMLの記述を終了します

パラメータ必須解説
指定できるパラメータはありません

[emb]　式評価結果の埋め込み

  • マクロ・変数・JS操作

exp で示された式を評価(実行)し、その結果を埋め込みます。
変数をシナリオ中に表示させたい場合に使います。

パラメータ必須解説
exp ◯ 評価するTJS（JS）式を指定します。ここで評価された式がembタグと置き換わります
  • サンプルコード

[eval exp="f.value1='変数の値だよ～ん'"]
とどこかで書いておいて、
[emb exp="f.value1"]
と書くと、この emb タグが 変数の値だよ～ん という内容に置き換わります。

[if]　条件分岐

  • マクロ・変数・JS操作

式を評価し、その結果が true ( または 0 以外 ) ならば、 elsif・else・endif のいずれかまでにある文章やタグを実行し、 そうでない場合は無視します。

パラメータ必須解説
exp ◯ 評価する TJS 式を指定します。この式の結果が false ( または 0 な らば、elsif・else・endif タグまでの文章やタグが無視されます。
  • サンプルコード

; 例1
[if exp="false"]
ここは表示されない
[else]
ここは表示される
[endif]

; 例2
[if exp="false"]
ここは表示されない
[elsif exp="false"]
ここは表示されない
[else]
ここは表示される
[endif]

; 例3
[if exp="false"]
ここは表示されない
[elsif exp="true"]
ここは表示される
[else]
ここは表示されない
[endif]

; 例4
[if exp="true"]
ここは表示される
[elsif exp="true"]
ここは表示されない
[else]
ここは表示されない
[endif]

[elsif]　それまでの if の中身が実行されていなかったときに、条件付きで実行

  • マクロ・変数・JS操作

if タグと endif タグの間で用いられます。 それまでの if タグまたは elsif タグの中身がひとつも実行されていないときに 式を評価し、その結果が真ならば elsif から次の elsif・else・endif までの間を実行します。
使い方の例については、if タグの項目を参照してください。

パラメータ必須解説
exp ◯ 評価する JS 式を指定します。

[else]　if の中身が実行されなかったときに実行

  • マクロ・変数・JS操作

if タグもしくは elsif タグ と endif タグの間で用いられます。 if または elsif ブロックの中身がひとつも実行されていないとき、 else から endif までの間を実行します。
使い方の例については、if タグの項目を参照してください。

パラメータ必須解説
指定できるパラメータはありません

[endif]　if文を終了します

  • マクロ・変数・JS操作

if文を終了します。必ずif文の終わりに記述する必要があります

パラメータ必須解説
exp × 評価する TJS 式を指定します。

[call]　サブルーチンの呼び出し

  • マクロ・変数・JS操作

指定されたシナリオファイルの指定されたラベルで示される サブルーチンを呼び出します。
呼び出されたサブルーチンは、 return タグで 呼び出し元や任意の場所に戻ることができます。

パラメータ必須解説
storage × 呼び出したいサブルーチンのあるのシナリオファイルを 指定します。省略すると、現在 のシナリオファイル内であると見なされます。
target × 呼び出すサブルーチンのラベルを指定します。省略すると、ファイルの先頭から実行されます。

[return]　サブルーチンから戻る

  • マクロ・変数・JS操作

サブルーチンから呼び出し元に戻ります。
KAG３の任意の場所へのリターンは廃止しました。
（必要な場合はCallで代用してください）

パラメータ必須解説
指定できるパラメータはありません

[macro]　マクロの記述

  • マクロ・変数・JS操作

マクロ記述を開始します。新しいタグを定義することが出来ます。
このタグから、endmacro タグまでにある文章やタグは、 name 属性で指定されたタグとして登録され、以後使用できるようになります。
マクロ中に書かれたタグには、特別に % を頭につけた属性の値を指定することができます。 % 以降にはマクロに渡された属性名を指定します。すると、マクロに渡された属性の値をその属性の値とすることができます。このとき、| を使って属性の省略値を指定することもできます ( 下の例参照 )。 属性名には小文字を用いてください。
また、属性の代わりに * を書くと、マクロに渡されたすべての属性をそのタグに渡すこと ができます。

パラメータ必須解説
name ◯ マクロの名前を指定してください。以後この名前で新しいタグが定義され呼び出せるようになります。
  • サンプルコード

[macro name="newtag"][font color=0xff0000]新しいタグです[resetfont][endmacro]
[newtag]
[macro name="colortag"][font color=%iro]iro 属性付きのタグ[resetfont][endmacro]
[colortag iro=0x332211]
; ↑ colotag に渡された iro 属性の値が font タグの color 属性に渡される
[macro name="transwait"][trans *][wt][endmacro]
; ↑ この transwait に渡されたすべての属性が trans タグに渡される
[macro name="colortag"][font color=%iro|0xff0000]iro 属性付きで省略値をしていしたタグ[resetfont][endmacro]
; ↑ % の属性の値では、 | のあとに続けて、その属性の省略値を指定することができます

[endmacro]　マクロを終了します

  • マクロ・変数・JS操作

マクロの終了タグです

パラメータ必須解説
指定できるパラメータはありません

[erasemacro]　マクロの削除

  • マクロ・変数・JS操作

登録したマクロを削除します

パラメータ必須解説
name ◯ 削除するマクロ名を記述してください

[savesnap]　セーブスナップの作成

  • システム操作

現在のプレイ状況を一時保存します。その後、tyrano.ks　拡張の[setsave]を行うことで、ここで記録したセーブデータが保存されます。

パラメータ必須解説
title ◯ セーブデータのタイトルを指定します。

[autosave]　オートセーブ機能

  • システム操作

このタグに到達した際、自動的にプレイ状況を保存します。自動セーブ機能に活用ください。
[autosave]されたデータが存在する場合、sf.system.autosaveにtrueが格納されます。
タイトル画面より前に、サンプルのような判定ロジックを用意しておくことで、
スマートフォンなどで、復帰後に事前にプレイしていた状態からゲームを開始することができるようになります。

パラメータ必須解説
title × セーブデータのタイトルを指定します。
  • サンプルコード


[autosave]

;autosaveされたデータが存在する場合、sf.system.autosave に trueが入ります
[if exp="sf.system.autosave ==true"]
自動的に保存されたデータが存在します。ロードしますか？[l][r]

[link target=*select1]【１】はい[endlink][r]
[link target=*select2]【２】いいえ[endlink][r]

[s]

*select1
;ロードを実行します
[autoload]

*select2
[cm]
ロードをやめました[l]
@jump target=*noload
[else]
自動的に保存されたデータはありません。[l][r]
[endif]


[autoload]　オートロード機能

  • システム操作

[autosave]タグで保存されたデータを読み込みます

パラメータ必須解説
指定できるパラメータはありません

[ignore]　条件によりシナリオを無視

  • マクロ・変数・JS操作

式を評価し、その結果が true ( または 0 以外 ) ならば、endignore タグまでにある文章 やタグが無視されます。

パラメータ必須解説
exp ◯ 評価する TJS 式を指定します。この式の結果が true ( または 0 以外 )ならば、endignore タグまでの文章やタグが無視されます。

[endignore]　ignoreの終了

  • マクロ・変数・JS操作

ignoreを終了します

パラメータ必須解説
指定できるパラメータはありません

[edit]　テキストボックス

  • 入力フォーム関連

テキストボックスを表示します。
入力された値はcommitタグのタイミングで指定した変数名に格納されます
フォーム表示中はシナリオは停止します。（クリックしてもストーリーが進まない）
必ず、グラフィックボタンなどを配置してラベルへジャンプしてください。
こまかい表示方法の変更はtyrano.css内を編集することで可能です。

パラメータ必須解説
name ◯ 格納する変数名を指定して下さい
length × 横幅です
initial × 初期値を設定することができます
color × 文字の色を指定して下さい　デフォルトは黒です
left × テキストボックスの横位置を指定します
top × テキストボックスの縦位置を指定します
size × 文字のサイズを指定します　デフォルト２０px
width × テキストボックスの幅サイズを指定します
height × テキストボックスの高さを指定します
maxchars × 最大入力文字数
  • サンプルコード

[edit name="f.test"]

[locate x=200 y=300 ]
[button graphic="start.png" target=*commit]

[s]

*commit
[commit name="f.test"]
[cm]
;入力されたテキストの内容を表示する
値が確定しました[l]
「[emb exp=f.test]」と入力しましたね[l]


[preload]　画像ファイルの事前読み込み

  • システム操作

preloadタグを使用することで、素材ファイル（画像や音楽）を事前に読み込んでおくことができます。
実際に素材を使用する際に表示がスムーズになります。

パラメータ必須解説
storage ◯ 事前に読み込む画像ファイルをフルパスでしていしてください。配列を渡すことでまとめて指定することもできます。
wait × trueを指定すると、全ての読み込みが完了するまでゲームを停止します。NowLoadingの表示が必要でしょう。true or false デフォルトはfalse
  • サンプルコード


;画像ファイルはフルパス（プロジェクトファイル以下）で指定してください
[preload storage="data/fgimage/girl.jpg"]

;配列を渡すと、まとめてロードすることもできます。
[iscript]
f.preload_images = ["data/fgimage/girl.jpg","data/fgimage/haruko.png","data/fgimage/miku1.png","data/fgimage/miku2.png"];
[endscript]

[preload storage=&f.preload_images]


[clearfix]　Fixレイヤーをクリアします。

  • レイヤ関連

name属性を指定することで、該当する要素のみを削除することもできます。

パラメータ必須解説
name × fixレイヤーへ追加した時に名前を指定した場合、適応できます。
  • サンプルコード


;fixレイヤーへの追加
[ptext name="sample" layer=fix page=fore text="テキストテキスト" size=30 x=200 y=100 color=red ]

;fixレイヤーのクリア
[clearfix name="sample"]


[commit]　フォームの確定

  • 入力フォーム関連

テキストボックスの値を確定して指定したname属性で指定した変数に値を格納します。
注意点としてcommitが実行された段階で、テキストボックスなどのフォームが表示されている必要があります。

パラメータ必須解説
指定できるパラメータはありません

[cursor]　マウスカーソルに画像を設定できいます

  • システム操作

storageに指定した画像ファイルがマウスカーソルに指定されます。data/imageフォルダ以下に配置してください。ファイルは形式は gif png jpg です。
ゲーム中に何度でも変更することが可能です。ゲームでの標準カーソルを指定する場合はsystem/Config.tjsのcursorDefaultを指定してください。
システムの標準カーソルに戻す場合はdefaultを指定します

パラメータ必須解説
storage ◯ カーソルに指定したい画像ファイルを指定します。画像はdata/imageフォルダに配置してください。
  • サンプルコード

[cursor storage="my_cursor.gif"]

[screen_full]　フルスクリーン

  • システム操作

ゲーム画面をフルスクリーンにします。PCゲームのみ動作します
ウィンドウに戻す場合は再度呼び出すことでウィンドウに戻ります

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[screen_full]

[sleepgame]　ゲームの一時停止

  • システム操作


このタグに到達した時点でゲームの状態を保存した上で、他のシナリオへ移動することができます。
そして遷移先で[awakegame]が実行されたらゲームに復帰できます。

このタグはゲームから一時的に画面を遷移したい場合に非常に強力に機能します。

例えば、ゲームの途中でコンフィグの設定を行いたい場合などは
sleepgameで進行状態を保持した上で、コンフィグ画面に移動します。[awakegame]タグでゲームに復帰します

sleepgameは複数実行することはできません。必ず[awakegame]を実行して下さい。
[awakegame]を実行しない場合は[breakgame]で休止中の状態を破棄します。

[button]で呼びたす場合、roleにsleepgameを指定すると、押された時にsleepgameを適応することができます。

パラメータ必須解説
storage × ゲームを中断して処理を始めるシナリオ名を記述します。省略された場合は、現在のファイル名と解釈されます
target × ジャンプする先のラベル名を指定できます。省略されている場合は先頭位置からと解釈されます
next × true か　falseを指定。 falseを指定するとawakegameで戻ってくる時に次の命令へ移らなくなります。デフォルトはtrue
  • サンプルコード


[sleepgame storage="scene3.ks" target="*start" ]

;buttonに紐付ける方法
[button name="button" role="sleepgame" fix="true" graphic="button/skip.gif" x=450 y=400 storage="scene3.ks" ]


[awakegame]　ゲームの一時停止からの復帰

  • システム操作

[gamesleep]タグで一時停止していたゲームを再開します。
ジャンプ先での変数操作 （f）については、ゲーム復旧後も反映されます。
ゲームに戻る前にmake.ksを通過します。ジャンプ先での操作に対して戻る前に設定を行いたい場合は
make.ksで変数fに対して、[awakegame]からの復帰かどうかの判定をいれるとよいでしょう。

パラメータ必須解説
variable_over × trueかfalseを指定します。trueを指定するとsleepgame中のゲーム変数への変更を引き継ぎます。デフォルトはtrue
bgm_over × trueかfalseを指定します。trueを指定するとsleepgame中のBGMを再生し続けます。デフォルトはtrue。falseだとsleepgame時のBGMに切り替わります。

[breakgame]　ゲームの停止データの削除

  • システム操作

[gamesleep]タグで一時停止していたゲームを削除します。
[gameawake]しない場合、このタグで削除してください。

パラメータ必須解説
指定できるパラメータはありません

[dialog]　ダイアログ表示

  • システム操作

確認用のダイアログを表示します。
ダイアログは以下のタイプがあります。
alert confirm input
inputはv470以降、廃止します。使用しないでください

パラメータ必須解説
name × confirmを指定した時に格納する変数名を指定して下さい。
type × ダイアログの種類を指定します。alert confirm
text × メッセージとして表示するてテキストを指定して下さい
storage × 指定されている場合はダイアログのボタンを押した後のジャンプ先シナリオファイルを指定します。省略すると、現在 のシナリオファイル内であると見なされます。
target × 指定されている場合はダイアログのボタンを押した後のジャンプ先ラベルを指定します。
storage_cancel × 指定されている場合はダイアログのキャンセルボタンを押した後のジャンプ先シナリオファイルを指定します。
target_cancel × 指定されている場合はダイアログのキャンセルボタンを押した後のジャンプ先ラベルを指定します。
label_ok × OKボタンの名前を好きなものに指定できます。デフォルトはOKです
label_cancel × キャンセルボタンの名前を好きなものに指定できます。デフォルトはCancelです
  • サンプルコード

;警告ウィンドウのメッセージ表示
[dialog type="alert" text="メッセージ内容" ]

;確認ダイアログの表示
[dialog type="confirm" text="メッセージ内容" storage="scene2" target="ok_label" storage_cancel="" target_cancel="" ]

;V470から廃止です。使用しないでください
;テキスト入力ダイアログの表示
[dialog type="input" text="名前を教えて下さい" storage="scene2" target="ok_label" ]


[plugin]　プラグイン読み込み

  • システム操作

外部プラグインを読み込むことができます。
プラグインはdata/others/plugin/　フォルダに配置します。

また、pluginタグは引数を自由に渡すことができます。
例えば
[plugin name="original1" font_color="black" myname="シケモク" ]

のようにすると、プラグイン先のinit.ks 内で
mp.font_color
mp.myname
のような形で引数を利用できます。

これを &mp.font_color のように使うことで、カスタマイズ可能なプラグインが作れます。
ただ、マクロで使用可能だった%font_color のような形の使用はできませんので注意。

パラメータ必須解説
name ◯ data/othres/plugin以下の配置したフォルダ名（プラグイン名）を指定する
storage × 最初に読み込むシナリオファイルを変更できます。デフォルトはinit.ks です。
  • サンプルコード

;テーマ変更
[plugin name="original1" ]

;自由に引数を渡すことも可能
[plugin name="original1" font_color="black" arg2="aaaaaa" ]


[sysview]　システム画面変更

  • システム操作

システム系機能で使用するHTMLファイルを変更できます。

パラメータ必須解説
type ◯ save load backlog menu が指定可能
storage ◯ HTMLファイルのパスを指定します。
  • サンプルコード

[sysview type="save" storage="./data/others/plugin/mytheme/html/save.html" ]
[sysview type="load" storage="./data/others/plugin/mytheme/html/load.html" ]
[sysview type="backlog" storage="./data/others/plugin/mytheme/html/backlog.html" ]
[sysview type="menu" storage="./data/others/plugin/mytheme/html/menu.html]


[loadcss]　CSS反映

  • システム操作

ゲームの途中でCSSを読み込むことができます。

パラメータ必須解説
file ◯ 読み込みたいCSSファイルを指定します
  • サンプルコード

;CSSファイルの読み込み
[loadcss file="./data/others/css/mystyle.css" ]


[save_img]　セーブ時のキャプチャイメージ変更

  • システム操作

セーブデータのサムネイルをキャプチャを変更することができます。
このタグで設定したイメージがセーブ時の画像として適応されます。
セーブ画像は「bgimage」フォルダから指定します。
storageに「default」と指定することで、従来の画面自動キャプチャに戻せます。

パラメータ必須解説
storage × 設定したいセーブ用画像を設定します。bgimageフォルダに配置してください。「default」を指定するとオートキャプチャに戻ります。
folder × bgimageフォルダ以外から取得したい場合は、ここに指定します。例えば、othersやfgimage、imageなどです。
  • サンプルコード

;サムネイル画像の変更
[save_img storage="my_capture.png" ]


[nolog]　バックログ記録停止

  • システム操作

このタグに到達すると、バックログへ一切追加されなくなります。
[endnolog]タグに到達すると、バックログへの記録が再開されます。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

ここはログに記録される[p]
[nolog]
ログに記録されない[p]
ここもログに記録されない[p]
[endnolog]
ここから、ログ記録再開[p]


[endnolog]　バックログ記録を再開する

  • システム操作

[nolog]タグでログ記録を停止している場合
この[endnolog]タグで記録を再開する必要があります。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

ここはログに記録される[p]
[nolog]
ログに記録されない[p]
ここもログに記録されない[p]
[endnolog]
ここから、ログ記録再開[p]


[pushlog]　バックログに文字列記録

  • システム操作

バックログに任意の文字列を追加できます。
例えば [mtext]などは通常バックログに記録されませんが
このタグを内包したマクロなどにしておくと、バックログに追加した
演出テキストなどが可能です。

パラメータ必須解説
text ◯ バックログに追加する文字列を追加できます
join × バックログを前の文字列に連結するか否かを指定できます。trueを指定すると前の文字列につなげます。デフォルトはfalse
  • サンプルコード

[pushlog text="ここに好きなログ文字列を記述できます"]


[start_keyconfig]　キーコンフィグ操作の有効化

  • システム操作

キーコンフィグが無効の場合、再開することができます。

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[start_keyconfig]


[stop_keyconfig]　キーコンフィグ操作の無効化

  • システム操作

キーコンフィグを一時的に無効にすることができます。
再開させる場合は[start_keyconfig]タグを使用してください。

無効になるのは
・マウス操作
・キーボード操作
・マウスのスワイプ操作

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[stop_keyconfig]
ここは無効。
ここも無効。
[start_keyconfig]
ここから、キーコンフィグ設定が有効。


[apply_local_patch]　パッチファイルを手動で反映します

  • システム操作

V470以降で使用可
パッケージングして配布している場合のみ有効。
このタグに到達した時点で、パッチファイルをゲームに反映することが可能。
dataフォルダ以外、tyrano本体をアップデートするときは
このタグではなく、起動時のアップデートで対応してください。
パッチファイルの容量が大きい場合は一時的にゲームが停止します。ロード中といった表記を表示すると親切です。

パラメータ必須解説
file ◯ パッチファイルのパスを指定してください。exeファイルの階層を起点として指定します
reload × true or false を指定。trueを指定すると反映後にゲームが再読込されます。デフォルトはfalse
  • サンプルコード

[apply_local_patch file="test.tpatch" ]


[check_web_patch]　サーバーからアップデートをチェックして反映させることができます。

  • システム操作

V470以降で使用可
サーバーにアップデートパッチを配置して更新がある場合
自動的にメッセージを表示して、パッチの適応を促すことができます。
サーバーをレンタルして json ファイルと tpatch ファイルを配置します。
また、反映するためには、一度ゲームを再起動する必要があります。

パラメータ必須解説
url ◯ サーバのjsonファイルのURLをhttp:// から指定してください
  • サンプルコード

[check_web_patch url="http://tyrano.jp/patch/mygame.json" ]


[loadjs]　外部JavaScriptファイル読み込み

  • マクロ・変数・JS操作

外部JavaScriptファイルをロードします
無制限な機能拡張が可能です
JSファイルは/data/others フォルダ以下に格納してください

パラメータ必須解説
storage ◯ ロードするJSファイルを指定します
  • サンプルコード

[loadjs storage="sample.js" ]

[movie]　ムービーの再生

  • その他

ogv webm mp4 などに対応します
提供するゲームによって対応するフォーマットが異なります。
PCゲーム形式の場合は webm形式を使ってください。 mp4 に対応しません。
ブラウザゲームの場合はmp4ファイルを使用します。ただし、FireFox Opera を含む全てのブラウザに対応させる場合は同名のwebmファイルも配置して下さい

パラメータ必須解説
storage ◯ 再生するogv webm mp4ファイルを指定してください
skip × 動画再生中に途中でスキップ可能か否かを指定します true か false を指定してください
volume × ビデオの音量を指定できます 0〜100の間で指定して下さい。デフォルトは100
  • サンプルコード

[movie storage="" skip=false ]

[bgmovie]　背景ムービーの再生

  • その他

ogv webm mp4 などに対応します
提供するゲームによって対応するフォーマットが異なります。
PCゲーム形式の場合は webm形式を使ってください。 mp4 に対応しません。
ブラウザゲームの場合はmp4ファイルを使用します。ただし、FireFox Opera を含む全てのブラウザに対応させる場合は同名のwebmファイルも配置して下さい
stop_bgmovie タグを指定すると再生が終わります。

bgmovieをループ中に別のbgmovieを重ねることで、ループが完了してから次の動画を再生させる事ができます。

（注意）このタグはPC限定です。スマホでは利用できません。

パラメータ必須解説
storage ◯ 再生するogv webm mp4ファイルを指定してください
time × 背景動画を表示するときにフェードアウト効果を与える時間を指定します。デフォルトは1000(ミリ秒)
volume × ビデオの音量を指定できます 0〜100の間で指定して下さい。デフォルトは100
loop × 背景動画をループさせるかどうかを指定します。falseを指定すると動画の最後の状態で停止します。
  • サンプルコード

[bgmovie storage="test.webm" ]

[wait_bgmovie]　背景ムービーの再生完了を待つ

  • その他

再生中の背景ムービーの完了を待ちます。

パラメータ必須解説
指定できるパラメータはありません

[stop_bgmovie]　背景ムービーの停止

  • その他

bgmovieで再生した背景動画を停止します。

パラメータ必須解説
time × ミリ秒で指定すると、動画をフェードアウトして削除することが可能です。デフォルトは1000
wait × trueかfalse を指定します。動画のフェードアウトを待つかどうかを指定できます。デフォルトはtrue
  • サンプルコード

[stop_bgmovie storage="" skip=false ]

[showsave]　セーブ画面を表示します

  • システム操作

セーブ画面を表示します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[showsave]

[showload]　ロード画面を表示します

  • システム操作

ロード画面を表示します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[showload]

[showmenu]　メニュー画面を表示します

  • システム操作

メニュ＾画面を表示します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[showmenu]

[showmenubutton]　メニューボタンを表示

  • システム操作

メニューボタンを表示します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[showmenubutton]

[hidemenubutton]　メニューボタンを非表示

  • システム操作

メニューボタンを非表示します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[hidemenubutton]

[skipstart]　スキップ開始

  • システム操作

文字表示をスキップモードにします。

パラメータ必須解説
指定できるパラメータはありません

[skipstop]　スキップ停止

  • システム操作

スキップモードを停止します。

パラメータ必須解説
指定できるパラメータはありません

[autostart]　オート開始

  • システム操作

文字表示を一定間隔で自動的に進めます。
進行速度はconfig.tjsのautoSpeedを確認して下さい

パラメータ必須解説
指定できるパラメータはありません

[autostop]　オート停止（）

  • システム操作

オートモードを停止します。

パラメータ必須解説
指定できるパラメータはありません

[autoconfig]　オート設定

  • システム操作

オートモードに関する設定

パラメータ必須解説
speed × オート時のスピードをミリ秒で指定して下さい
clickstop × 画面クリック時にオートを停止するかどうかを指定します true(停止する デフォルト) false（停止しない）

[anim]　アニメーション

  • アニメーション関連

画像やボタン、レイヤなどの中身をアニメーションさせることができます
アニメーションさせる要素は[image][ptext][button]タグ作成時にname属性で指定した名前を利用できます。
レイヤを指定するとレイヤの中にある要素全てを同時にアニメーションできます
このタグはアニメーションの終了を待ちません。[wa]タグを使用すると実行中のすべてのアニメーションの完了を待つことができます。
位置のアニメーションは指定する値に+=100 -=100　と指定することで相対位置指定できます（今表示されているところから、右へ１００PX移動といった指定ができます）
透明度を指定すれば、アニメーションしながら非表示にすることもできます。

パラメータ必須解説
name × ここで指定した値が設定されている要素に対してアニメーションを開始します。name属性で指定した値です。
layer × name属性が指定されている場合は無視されます。前景レイヤを指定します。必ずforeページに対して実施されます。
left × 指定した横位置にアニメーションで移動します。
top × 指定した縦位置にアニメーションで移動します。
width × 幅を指定します
height × 高さを指定します
opacity × 0～255の値を指定します。指定した透明度へアニメーションします
color × 色指定
time × アニメーションにかける時間をミリ秒で指定して下さい。デフォルトは2000ミリ秒です
effect × 変化のエフェクトを指定します。指定できる文字列は以下の種類です
jswing｜def｜easeInQuad｜easeOutQuad｜easeInOutQuad｜easeInCubic｜easeOutCubic｜easeInOutCubic｜easeInQuart｜easeOutQuart｜easeInOutQuart｜easeInQuint｜easeOutQuint｜easeInOutQuint｜easeInSine｜easeOutSine｜easeInOutSine｜easeInExpo｜easeOutExpo｜easeInOutExpo｜easeInCirc｜easeOutCirc｜easeInOutCirc｜easeInElastic｜easeOutElastic｜easeInOutElastic｜easeInBack｜easeOutBack｜easeInOutBack｜easeInBounce｜easeOutBounce｜easeInOutBounce
  • サンプルコード

[ptext layer=1 page=fore text="文字列" size=30 x=0 y=0 color=red vertical=true]

[image layer=0 left=100 top=100 storage = yuko1.png page=fore visible=true name=yuko,chara ]
[image layer=1 left=300 top=100 storage = haruko1.png page=fore visible=true name=haruko ]

;name属性を指定してアニメーション
[anim name=haruko left="+=100" time=10000 effect=easeInCirc opacity=0 ]

;レイヤを指定してアニメーション
[anim layer=1 left="+=100" effect=easeInCirc opacity=0 ]

;すべてのアニメーション完了を待ちます
[wa]

アニメーション終了


[wa]　アニメーション終了待ち

  • アニメーション関連

実行中のアニメーションすべて終了するまで処理を待ちます

パラメータ必須解説
指定できるパラメータはありません

[stopanim]　アニメーション強制停止

  • アニメーション関連

実行中のアニメーションを強制的に停止します。

パラメータ必須解説
name ◯ ここで指定した値が設定されている要素に対してアニメーションを停止します

[keyframe]　キーフレームアニメーション定義

  • アニメーション関連

キーフレームアニメーションを定義します。定義したアニメーションは[kanim]タグで指定することで使用できます

パラメータ必須解説
name ◯ キーブレームの名前を指定します。後に[kanim]タグを使用する際に指定する名前になります
  • サンプルコード


;----keyframeの定義
[keyframe name="fuwafuwa"]

[frame p=40% x="100" ]
[frame p=100% y="-200" opacity=0 ]

[endkeyframe]

;-----定義したアニメーションを実行


[endkeyframe]　キーフレームアニメーション定義を終了します

  • アニメーション関連

キーフレームアニメーション定義を終了します

パラメータ必須解説
指定できるパラメータはありません

[frame]　キーフレームアニメーション定義

  • アニメーション関連

キーフレームアニメーションを定義します。定義したアニメーションは[kanim]タグで指定することで使用できます

パラメータ必須解説
p ◯ パーセンテージを指定してください。例えば５秒かかるアニメーションに対して20%の位置という指定になります。0〜100%の間で指定してください。0%を省略することで前回のアニメーション状態を継承して新しいアニメーションを開始できます。
x × X軸方向へのアニメーション量をpxで指定して下さい。　また、*(アスタリスク)で始めることで、絶対位置として指定することができます。（例） x＝"100"（前へ100px移動する） x
y × Y軸方向へのアニメーション量をpxで指定して下さい。　また、*(アスタリスク)で始めることで、絶対位置として指定することができます。（例） y＝"100"（前へ100px移動する） y
z × Z軸方向へのアニメーション量をpxで指定して下さい。　また、*(アスタリスク)で始めることで、絶対位置として指定することができます。（例） z＝"100"（前へ100px移動する） z
rotate × 対象を回転させることができます。例　rotate＝"360deg"のような形で指定して下さい（３６０度回転）
rotateX × 対象をX軸を軸として回転させることができます。例　rotateX＝"360deg"のような形で指定して下さい（３６０度回転）
rotateY × 対象をY軸を軸として回転させることができます。例　rotateY＝"360deg"のような形で指定して下さい（３６０度回転）
rotateZ × 対象をZ軸を軸として回転させることができます。例　rotateZ＝"360deg"のような形で指定して下さい（３６０度回転）
scale × 対象を拡大、縮小することができます。例　scale＝"2" (２倍に拡大します) scale＝"0.5" 半分に縮小します
scaleX × X方向に拡大、縮小できます
scaleY × Y方向に拡大、縮小できます
scaleZ × Z方向に拡大、縮小できます
skew × 傾斜
skewX × X傾斜
skewY × Y傾斜
perspective × 遠近効果を付与することができます。一部ブラウザのみ
opacity × 0～1を指定することで、各要素の透明度を指定することができます、非表示にしたりすることができます。0で完全に透明になります。その他

[kanim]　キーフレームアニメーションの実行

  • アニメーション関連

キーフレームアニメーションを実行します。[keyframe]タグで定義した名前とアニメーションさせる画像やテキストを指定することで
複雑なアニメーションを実現できます。

パラメータ必須解説
name × アニメーションさせる画像やテキストのnameを指定してください
layer × nameを指定せずに、layerを指定することでそのlayerに属するエレメント全てにアニメーションを適用させることができます
keyframe ◯ 実行するキーフレームアニメーション名を指定してください。
time × アニメーションを実行する時間をミリ秒で指定してください。
easing × アニメーションの変化パターンを指定することができます。指定できる値としてease(開始時点と終了時点を滑らかに再生する)　linear(一定の間隔で再生する)ease-in(開始時点をゆっくり再生する)ease-out(終了時点をゆっくり再生する)ease-in-out(開始時点と終了時点をゆっくり再生する)この他に、cubic-bezier関数を使って、イージングを独自に設定することも可能です
count × 再生回数を指定できます。初期値は１。"infinite"を指定することで無限にアニメーションさせることもできます。
delay × 開始までの時間を指定できます。初期値は遅延なし(0)です。
direction × 偶数回のアニメーションを逆再生するか指定できます。 初期値は"normal" 偶数回逆再生させる場合は、"alternate"を指定します
mode × 再生前後の状態を指定できます。初期値は"forwards"で再生後の状態を維持します。 "none"を指定すると、再生後の状態を維持しません

[stop_kanim]　キーフレームアニメーションの停止

  • アニメーション関連

キーフレームアニメーションを停止します。

パラメータ必須解説
name × アニメーションさせる停止する画像やテキストのnameを指定してください
layer × nameを指定せずに、layerを指定することでそのlayerに属するエレメント全てにアニメーション停止を適用させることができます

[chara_ptext]　キャラクターの発言名前欄表示と表情変更

  • キャラクター操作

[chara_config ptext="hogehoge"]という形式で定義した発言者のメッセージボックスにnameで指定した名前を設定できます。
さらに、faceパラメータを指定することで、同時に表情も変更できます。
このタグには省略して書くことができます。
#chara_name:face_name と　[ptext name="chara_name" face="face_name"] は同じ動作をします。
[chara_new]時に登録した画像ファイルはface="default"で指定できます。
[chara_new name="yuko" storage="yuko.png" jname="ゆうこ"]

パラメータ必須解説
name × [chara_new]で定義したnameを指定します。紐づいたjnameがptext欄に表示されます
face × [chara_face]で定義したface名を指定してください
  • サンプルコード



[chara_config]　キャラクター操作タグの基本設定

  • キャラクター操作

キャラクター操作タグの基本設定を変更できます

パラメータ必須解説
pos_mode × true か false　を指定します。デフォルトはtrueです。trueの場合は、[chara_show]タグなどで追加した時の立ち位置を自動的に計算し、配置します。
ptext × 発言者の名前領域のptextを指定できます。例えば[ptext name
time × 0以上の数値をミリ秒で指定することで、[chara_mod]タグで表情を変える際に、クロスフェードの効果を与えることができます。指定時間かけて切り替わります。デフォルトは600ミリ秒です。0を指定すると即時に切り替わります
memory × true か false を指定します。デフォルトはfalseです。キャラクターを非表示にして再度表示した時に、表情を維持するかどうかをしていできます。falseをしていすると、[chara_new]で指定してデフォルトの表情で表示されます
anim × キャラクターを自動配置する場合、キャラクターの立ち位置が変わるときにアニメーションを行うか否かを指定できます。デフォルトは true です。falseを指定するとじんわりと入れ替わる効果に切り替わります。
pos_change_time × キャラクターの位置を変更する際のスピードを調整できます。ミリ秒で指定して下さい。デフォルトは600
talk_focus × 現在話しているキャラクターの立ち絵に対して、目立たせる演出が可能になります。指定できるのは brightness（明度） blur（ぼかし） none （無効）です。デフォルトはnone　どのキャラクターが話しているかの指定は #yuko のように指定すると、chara_new時の名前とひも付きます。
brightness_value × brightnessの値を指定できます。話しているキャラクター以外の明度を指定します。0〜100 で指定して下さい。デフォルトは60
blur_value × blurの値を指定できます。話しているキャラクター以外のぼかし方を指定します。0〜100 で指定して下さい。デフォルトは2 値がおおきいほどぼかしが強くなります
talk_anim × 現在話しているキャラクターの立ち絵に対して、ピョンと跳ねるような効果を与えることができます。指定できるのは up（上に跳ねる） down（下に沈む） none （無効）です。デフォルトはnone　どのキャラクターが話しているかの指定は #yuko のように指定すると、chara_new時の名前とひも付きます。
talk_anim_time × talk_animが有効な場合のアニメーション速度を指定できます。デフォルトは230ミリ秒。
talk_anim_value × talk_animが有効な場合のアニメーション量を指定できます。デフォルトは30。数値で指定してください。
effect × キャラクターが位置を入れ替わる際のエフェクト（動き方）を指定できます。jswing｜def｜easeInQuad｜easeOutQuad｜easeInOutQuad｜easeInCubic｜easeOutCubic｜easeInOutCubic｜easeInQuart｜easeOutQuart｜easeInOutQuart｜easeInQuint｜easeOutQuint｜easeInOutQuint｜easeInSine｜easeOutSine｜easeInOutSine｜easeInExpo｜easeOutExpo｜easeInOutExpo｜easeInCirc｜easeOutCirc｜easeInOutCirc｜easeInElastic｜easeOutElastic｜easeInOutElastic｜easeInBack｜easeOutBack｜easeInOutBack｜easeInBounce｜easeOutBounce｜easeInOutBounce

[chara_new]　キャラクターの定義

  • キャラクター操作

登場するキャラクターの情報を定義します。その後[chara_show ]で指定した名称で表示したり、画像を変更したりできます。
また、ここで定義したname属性は[anim]タグなどからも指定可能です。
つまり、キャラクターを追加したあとアニメーションすることも自由にできます。

パラメータ必須解説
name ◯ キャラクターを以後操作するための名前を半角英数で指定します。このnameは他のタグを含めて必ずユニークでなければなりません
storage ◯ キャラクター画像を指定してください。画像ファイルはプロジェクトフォルダのfgimageフォルダに配置してください
width × 画像の横幅を指定できます
height × 画像の高さを指定できます。
reflect × 画像を反転します
color × キャラクターの名前を表示するときの色を指定できます。0xRRGGBB 形式で指定します。
jname × このキャラクターをネームスペースに表示する場合、適用する名称を指定できます。例えば、#yuko と指定すると　メッセージエリアに　ゆうこ　と表示できます
  • サンプルコード

[chara_new name="yuko" storage="yuko.png" jname="ゆうこ"]

[chara_show]　キャラクターの登場

  • キャラクター操作

定義しておいたキャラクターを画面に表示します

パラメータ必須解説
name ◯ [chara_new]で定義したname属性を指定してください。
time × "ミリ秒で指定します。指定した時間をかけて登場します。デフォルトは1000ミリ秒です"
layer × "キャラクターを配置するレイヤーを指定できます。デフォルトは前景レイヤ layer
zindex × "キャラクターの重なりを指定できます。ここで指定した値が大きいほうが前に表示することができます。指定しない場合は後に登場するキャラクターが前に表示されます"
page × "foreかbackを指定します。デフォルトはforeです"
wait × "trueを指定すると、キャラクターの登場完了を待ちます。デフォルトはtrue です。"
face × [chara_face]で定義したface属性を指定してください。
storage × 変更する画像ファイルを指定してください。ファイルはプロジェクトフォルダのfgimageフォルダに配置します。
reflect × "trueを指定すると左右反転します"
width × "キャラクターの横幅を指定できます。"
height × "キャラクターの縦幅を指定できます。"
left × "キャラクターの横位置を指定できます。指定した場合、自動配置が有効であっても無効になります。"
top × "キャラクターの縦位置を指定できます。指定した場合、自動配置が有効であっても無効になります。"
  • サンプルコード

[chara_show name="yuko" ]

[chara_hide]　キャラクターの退場

  • キャラクター操作

[chara_show]タグで表示したキャラクターを退場させます。

パラメータ必須解説
name ◯ [chara_new]で定義したname属性を指定してください。
wait × trueを指定すると、キャラクターの退場を待ちます。デフォルトはtrueです。
time × ミリ秒で指定します。指定した時間をかけて退場します。デフォルトは1000ミリ秒です
layer × 削除対象のレイヤ。chara_showの時にレイヤ指定した場合は、指定します。デフォルトは０
pos_mode × キャラクターの立ち位置自動調整が有効な場合にこの値にfalseを指定すると退場後に立ち位置の調整を行いません。デフォルトはtrueです
指定できるパラメータはありません
  • サンプルコード

[chara_hide name="yuko" ]

[chara_hide_all]　キャラクターを全員退場

  • キャラクター操作

[chara_show]タグで表示したキャラクターを全員退場させます。

パラメータ必須解説
wait × trueを指定すると、キャラクターの退場を待ちます。デフォルトはtrueです。
time × ミリ秒で指定します。指定した時間をかけて退場します。デフォルトは1000ミリ秒です
layer × 削除対象のレイヤ。chara_showの時にレイヤ指定した場合は、指定します。デフォルトは０
  • サンプルコード

[chara_hide_all time=1000 wait=true]

[chara_delete]　キャラクター情報の削除

  • キャラクター操作

定義しておいたキャラクター情報を削除します。（画面から消す場合は[chara_hide]を使用してください）

パラメータ必須解説
name ◯ [chara_new]で定義したname属性を指定してください。
  • サンプルコード

[chara_delete="yuko" ]

[chara_mod]　キャラクター画像変更

  • キャラクター操作

画面のキャラクター画像を変更します。表情を変更する場合などに便利でしょう

パラメータ必須解説
name ◯ [chara_new]で定義したname属性を指定してください。
face × [chara_face]で定義したface属性を指定してください
time × 0以上の数値をミリ秒で指定することで、[chara_mod]タグで表情を変える際に、クロスフェードの効果を与えることができます。指定時間かけて切り替わります。デフォルトは600ミリ秒です。0を指定すると即時に切り替わります
reflect × trueを指定すると左右反転します
storage × 変更する画像ファイルを指定してください。ファイルはプロジェクトフォルダのfgimageフォルダに配置します。
wait × 表情の変更完了を待つか否かを指定します。true or falseで指定。デフォルトは true
cross × true or false を指定します。デフォルトはtrue。trueを指定すると２つの画像が同じタイミングで透明になりながら入れ替わります。falseを指定すると、古い表情を残しながら上に重なる形で新しい表情を表示します。
  • サンプルコード

[chara_mod name="yuko" storage="newface.png"]

[chara_move]　キャラクターの位置変更

  • キャラクター操作

画面のキャラクター立ち位置を変更します。

パラメータ必須解説
name ◯ [chara_new]で定義したname属性を指定してください。
time × 0以上の数値をミリ秒で指定することで、指定時間かけて位置を移動します切り替わります。600ミリ秒です。
anim × trueかfalseを指定します。デフォルトはfalse。trueを指定すると、位置を変える時にアニメーションさせることができます。アニメーション効果は[chara_config]のeffectパラメータを参照します
left × 移動先のヨコ位置を指定できます。「left
top × 移動先のタテ位置を指定できます。「top
width × 変更後の横幅を指定できます
height × 変更後の高さを指定できます
wait × 位置変更を待つか否かを指定します。true or falseで指定。デフォルトは true
effect × 変化のエフェクトを指定します。指定できる文字列は以下の種類です
jswing｜def｜easeInQuad｜easeOutQuad｜easeInOutQuad｜easeInCubic｜easeOutCubic｜easeInOutCubic｜easeInQuart｜easeOutQuart｜easeInOutQuart｜easeInQuint｜easeOutQuint｜easeInOutQuint｜easeInSine｜easeOutSine｜easeInOutSine｜easeInExpo｜easeOutExpo｜easeInOutExpo｜easeInCirc｜easeOutCirc｜easeInOutCirc｜easeInElastic｜easeOutElastic｜easeInOutElastic｜easeInBack｜easeOutBack｜easeInOutBack｜easeInBounce｜easeOutBounce｜easeInOutBounce
  • サンプルコード

[chara_move name="yuko" time=100 left=20 top=100 ]

[chara_face]　キャラクター表情登録

  • キャラクター操作

キャラクターの表情画像を名称と共に登録できます

パラメータ必須解説
name ◯ [chara_new]で定義したname属性を指定してください。
face ◯ 登録する表情の名前を指定してください
storage ◯ 変更する画像ファイルを指定してください。ファイルはプロジェクトフォルダのfgimageフォルダに配置します。
  • サンプルコード


;表情の登録
[chara_face name="yuko" face="angry" storage="newface.png"]
;表情の適応
[chara_mod name="yuko" face="angry"]
;発言者の名前も同時にかえたい場合
[chara_ptext name="yuko" face="angry"]
;短縮して書けます。以下も同じ意味
#yuko:angry
;chara_new で登録した画像はdefaultという名前で指定可能
#yuko:default


[chara_layer]　キャラクターの差分パーツ定義

  • キャラクター操作

キャラクターの表情を差分パーツを定義します。
デフォルトのパーツは一番最初に登録したものになります。

パラメータ必須解説
name ◯ [chara_new]で定義したname属性を指定してください。
part ◯ パーツとして登録する名を指定します。例えば「目」というpartを登録しておいて、このpartの中で他の差分をいくつも登録することができます。
id ◯ パーツの中で差分にidを登録できます。例えば「目」というpartの中で「笑顔の目」「泣いてる目」のようにidを分けてstorageを登録してください
storage ◯ 差分として登録する画像を指定します。画像はfgimageフォルダの中に配置します。noneを指定するとデフォルトそのパーツがない状態を表現することができます
zindex × 数値を指定します。このpartが他のパーツ重なった時にどの位置に表示されるかを指定します。数値が大きい程、前面に表示されます。一度登録しておけば該当するpartに適応されます。
  • サンプルコード

[chara_layer name="yuko" part=mouse id=egao storage="image/egao.png" ]

[chara_layer_mod]　キャラクターの差分の定義を変更

  • キャラクター操作

chara_layerで定義した設定を変更することができます。

パラメータ必須解説
name ◯ [chara_new]で定義したname属性を指定してください。
part ◯ 変更したいパーツとして登録した名を指定します。
zindex × 数値を指定します。このpartが他のパーツ重なった時にどの位置に表示されるかを指定します。数値が大きい程、前面に表示されます。この設定は即時反映されず、次回表示時、反映されます。
  • サンプルコード

[chara_layer_mod name="yuko" part=mouse zindex=20 ]

[chara_part]　キャラクターの差分パーツ変更

  • キャラクター操作

[chara_layer]で指定した差分を実際に表示切り替えする
このタグは特殊なパラメータ指定で[chara_layer]で定義したpart と id の組み合わせをパラメータとして自由に指定できます。
（例）eye=sample1
同時に複数のpartを変更することも可能です。
また、id登録していない、画像を直接指定することもできます。この場合パラメータのallow_storageにtrueに指定してください。
特定部位のzindexを変更して出力したい場合はpart名+_zindex という名前のパラメータに数値を代入することができます。
（例）eye_zindex=10

パラメータ必須解説
name ◯ [chara_new]で指定したキャラクター名を指定してください。
time × パーツが表示されるまでの時間を指定できます。ミリ秒で指定してください。指定するとフェードインしながら表示できます。デフォルトは指定なしです。
wait × true or false を指定します。trueを指定するとtimeで指定したフェードインの完了を待ちます。デフォルトはtrueです。
allow_storage × true or false 。partの指定にidではなく直接画像ファイルを指定できます。画像はfgimageフォルダに配置してください。デフォルトはfalseです。
  • サンプルコード

[chara_part name="yuko" mouse=aaa eye=bbb ]

[chara_part_reset]　キャラクターの差分パーツをデフォルトに戻す

  • キャラクター操作

[chara_part]で差分を変更した際、デフォルトの表情に戻すことができます。
キャラクターが表示されている場合は即時デフォルトに戻ります。

パラメータ必須解説
name ◯ [chara_new]で指定したキャラクター名を指定してください。
part × 特定のpartに絞ってリセットすることが可能です。デフォルトはすべてをデフォルトに戻します。ここに記述することで指定したpartのみリセットされます。カンマで区切ると複数指定することが可能です
  • サンプルコード

[chara_part_reset name="yuko" ]

[showlog]　バックログを表示します

  • システム操作

バックログを表示します

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード

[showlog]

[filter]　フィルター効果演出

  • レイヤ関連

レイヤやオブジェクトを指定して、様々なフィルター効果を追加することができます。


パラメータ必須解説
layer × 効果を追加するレイヤを指定します。指定しない場合、もしくは「all」と指定するとゲーム画面全てに効果がかかります
name × 削除する要素のnameを指定します。レイヤの中のあらゆるオブジェクトに適応できます。
grayscale × 0(デフォルト)-100 を指定することで、画像の表示をグレースケールに変換することができます
sepia × 0(デフォルト)-100を指定することで、画像の表示をセピア調に変換することができます
saturate × 0-100(デフォルト)を指定してあげることで、画像の表示の彩度（色の鮮やかさ）を変更することができます
hue × 0(デフォルト)-360を指定することで、画像の表示の色相を変更することができます
invert × 0(デフォルト)-100を指定することで、画像の表示の階調を反転させることができます
opacity × 0-100(デフォルト)を指定することで、画像の表示の透過度を変更することができます
brightness × 0-100(デフォルト)を指定することで、画像の表示の明るさを変更することができます。元画像より暗くしたい場合に使えます
contrast × 0-100(デフォルト)を指定することで、画像の表示のコントラストを変更することができます
blur × 0(デフォルト)-任意の値[px] を指定することで、画像の表示をぼかすことができます
  • サンプルコード


;特定のオブジェクトを指定して、フィルター効果。
[filter layer="0" name="chara_a" grayscale=50 ]

;レイヤを指定してフィルター効果
[filter layer="0" grayscale=50 ]



[free_filter]　フィルター効果削除

  • レイヤ関連

レイヤやオブジェクトを指定して、filter効果を無効にします。
指定されない場合はすべてのフィルター効果が無効化されます。

パラメータ必須解説
layer × フィルターを打ち消すレイヤを指定します。指定がない場合、すべての効果が消されます
name × フィルターを打ち消したい、nameを指定します。レイヤの中のあらゆるオブジェクトに適応できます。
  • サンプルコード


;特定のオブジェクトを指定して、フィルターを打ち消す。
[free_filter layer="0" name="chara_a"]

;全部のフィルターを打ち消す
[free_filter ]



[web]　Webサイトを開く

  • その他

指定したWebサイトをブラウザで開くことができます。
ただし、このタグを配置する直前にクリック待ちを配置する必要があります。
多くの環境で、ユーザーアクションなしにブラウザが開くことを禁止しています。

パラメータ必須解説
url ◯ 開きたいWebサイトのURLを入れてください。
  • サンプルコード


;クリック待ちを挟む
公式サイトを開きます[p]
[web url="http://tyrano.jp"]


[camera]　カメラを移動する

  • カメラ操作

カメラをズームやパンさせる演出を追加できます。
この機能を使うと、立ち絵のキャラクター表情にフォーカスをあてたり
一枚絵であっても多彩な演出が可能になります。

カメラ機能を使用するにはConfig.tjs の useCameraをtrueにする必要があります。
また、カメラ機能を有効にした場合、画面の中央寄せ（ScreenCentering）が無効になります。

カメラの座標は画面中央が(x:0,y:0)です。
例えば、画面右上は x:200 y:200 　画面左下は x:-200 y:-200 という座標指定になります。

カメラを元の位置に戻すためには[reset_camera]タグを使用します。
カメラの演出完了を待ちたい場合は[wait_camera]タグを使用します。

【重要】
カメラ演出が終わったら、必ず[reset_camera]でカメラの位置を初期値に戻して下さい。
カメラを戻さないと、背景の変更 [bg]タグ等は使用できません。

パラメータ必須解説
time × カメラが座標へ移動する時間を指定できます。ミリ秒で指定して下さい。デフォルトは1000
x × カメラの移動するX座標を指定して下さい
y × カメラの移動するY座標を指定して下さい
zoom × カメラの拡大率を指定して下さい。例えば２と指定すると２倍ズームします
rotate × カメラの傾きを指定します。例えば20 だとカメラが20度傾きます。
from_x × カメラの移動開始時のX座標を指定できます
from_y × カメラの移動開始時のY座標を指定できます
from_zoom × カメラの移動開始時の倍率を指定できます
from_rotate × カメラの移動開始時の傾きを指定できます
wait × カメラ移動の完了を待つかどうかを指定します。falseを指定するとカメラ移動中もゲームを進行することができます。デフォルトはtrue
layer × レイヤを指定します。背景ならbase 前景レイヤならう 0以上の数字。カメラの効果を特定レイヤだけに適応できます。
ease_type × カメラの移動演出を指定できます。ease(開始時点と終了時点を滑らかに再生する)linear(一定の間隔で再生する)ease-in(開始時点をゆっくり再生する)ease-out(終了時点をゆっくり再生する)ease-in-out(開始時点と終了時点をゆっくり再生する)デフォルトはeaseです。
  • サンプルコード


@camera zoom=2 x=180 y=100 time=1000
@camera x=-180 y=100 time=2000
@camera zoom=2 from_zoom=3 x=180 y=100 time=1000

;カメラの位置を元に戻す
@reset_camera


[reset_camera]　カメラをリセットする

  • カメラ操作

カメラの位置を初期値に戻します。
[camera]タグを使った演出が終わった後は、必ず[reset_camera]で位置を元に戻して下さい。
位置を戻さない場合は背景変更などで不具合が生じる場合があります。

パラメータ必須解説
time × 初期位置にカメラが移動する時間をミリ秒で指定します。デフォルトは1000です。
wait × カメラ移動の完了を待つかどうかを指定します。falseを指定するとカメラ移動中もゲームを進行することができます。デフォルトはtrue
ease_type × カメラの戻り方を指定できます。デフォルトはease　詳細はcameraタグを確認。
layer × レイヤを指定します。背景ならbase 前景レイヤならう 0以上の数字。カメラの効果を特定レイヤだけに適応できます。

[wait_camera]　カメラの演出を待つ

  • カメラ操作

このタグはカメラの操作中である場合、完了を待つことができます。
例えば、cameraタグでwaitにfalseを指定して、ゲームを進行する場合、特定の位置で必ずカメラ演出の完了を待たせる事が出来ます

パラメータ必須解説
指定できるパラメータはありません
  • サンプルコード


[camera zoom=2 x=180 y=100 time=5000]
カメラ演出中[p]
ここでもカメラ演出中[p]
[wait_camera]
カメラの演出が終わったので進行[p]


[mask]　スクリーンマスク表示

  • レイヤ関連

ゲーム画面全体を豊富な効果とともに暗転させることができます。
暗転中にゲーム画面を再構築して[mask_off]タグでゲームを再開する使い方ができます。

パラメータ必須解説
time × 暗転が完了するまでの時間をミリ秒で指定できます
effect × 暗転の効果を指定できます。デフォルトは「fadeIn」指定できるのは次のとおりですfadeIn/fadeInDownBig/fadeInLeftBig/fadeInRightBig/
fadeInUpBig/flipInX/flipInY/lightSpeedIn/
rotateIn/rotateInDownLeft/rotateInDownRight/rotateInUpLeft/
rotateInUpRight/zoomIn/zoomInDown/zoomInLeft/
zoomInRight/zoomInUp/slideInDown/slideInLeft/
slideInRight/slideInUp/bounceIn /bounceInDown/bounceInLeft/
bounceInRight/bounceInUp/rollIn
color × 文字の色を指定して下さい。デフォルトは黒です。0xFFFFFF形式で指定します
graphic × 暗転部分に独自画像を指定できます。画像はimageフォルダに配置してください
folder × graphicで指定するフォルダをimage以外に変更したい場合はこちらに記述します。例えばbgimage fgimageなどです
  • サンプルコード

;暗転開始
[mask effect="fadeInDownBig" time=2000]

;裏で画面操作
[bg storage="umi.jpg" time=500]

;暗転解除
[mask_off]


[mask_off]　スクリーンマスク消去

  • レイヤ関連

スクリーンマスクを消去してゲームを再開します。

パラメータ必須解説
time × 暗転が完了するまでの時間をミリ秒で指定できます
effect × 暗転の効果を指定できます。デフォルトは「fadeOut」指定できるのは次のとおりですfadeOut/fadeOutDownBig/fadeOutLeftBig/fadeOutRightBig/fadeOutUpBig/flipOutX/
flipOutY/lightSpeedOut/rotateOut/rotateOutDownLeft/rotateOutDownRight/
rotateOutUpLeft/rotateOutUpRight/zoomOut/zoomOutDown/
zoomOutLeft/zoomOutRight/zoomOutUp/slideOutDown/
slideOutLeft/slideOutRight/slideOutUp/
bounceOut /bounceOutDown/bounceOutLeft/
bounceOutRight/bounceOutUp
  • サンプルコード

;暗転開始
[mask effect="fadeInDownBig" time=2000]

;裏で画面操作
[bg storage="umi.jpg" time=500]

;暗転解除
[mask_off]


サポートサイト

関連サイト

Contact Us

お問い合せ、ご質問は以下のメールアドレスまでお願い致します
Email: shikemokumk@gmail.com

2016 © STRIKEWORKS All Rights Reserved.