使い方＆チュートリアル

それでは、いよいよキャラクターをゲームに登場させてみましょう。
キャラクターは以下の２人に登場してもらいます。それぞれ、「yuko1.png」「haruko1.png」というファイル名で プロジェクトフォルダの「fgimage」に保存して下さい。
（注）透過処理が施されたファイルを準備して下さい


【画像】　yuko1.png　と　haruko1.png
　

それでは、２名を登場させるスクリプトを記述してみましょう。

*start

;背景画像の切り替え実行
[bg storage=room.jpg time=3000]

背景が切り替わりましたね？

;１人目のキャラクター登場
[chara_new name="yuko" storage="yuko1.png" jname="ゆうこ"]
[chara_show name="yuko"]
ゆうこが登場しました！[l][r]

;２人目のキャラクター登場
[chara_new name="haruko" storage="haruko1.png" jname="はるこ"]
[chara_show name="haruko"]
はるこが登場しました！[l][r]

					

保存して、実行してみてみましょう

実行結果


キャラクターが表示されていますね。
それでは、解説していきます

[chara_new name="yuko" storage="yuko1.png" jname="ゆうこ"]
[chara_show name="yuko"]

[chara_new]タグはキャラクターを定義する命令です
１人につき、一回、登場する前に記述する必要があります。

そして、name属性はキャラクターの名前を半角英数字で指定します。
storage属性 は表示する画像ファイルを指定します。
jname属性はキャラの日本語名を登録します

最後に[chara_show]タグで定義したキャラクターを表示します。
name属性で指定したキャラクターが画面に登場しましたね。

会話の内容によって、キャラクターの表情を変えるとゲームが華やかになりますね
ティラノスクリプトでも、もちろん対応しています。

それでは、先ほど登場した　ゆうこ　の新しい表情を用意します。このファイルを「yuko2.png」としてfgimageフォルダに入れます。



すこし怒ったような表情ですね。
先ほどのスクリプトに付け足す形で、表情を変更してみましょう。

*start

;１人目のキャラクター登場
[chara_new name="yuko" storage="yuko1.png" jname="ゆうこ"]
[chara_show name="yuko"]

ゆうこが登場しました！[l][r]

;２人目のキャラクター登場
[chara_new name="haruko" storage="haruko1.png" jname="はるこ"]
[chara_show name="haruko"]

はるこが登場しました！[l][r]


;ゆうこの表情を登録
[chara_face name="yuko" face="angry" storage="yuko2.png"]

表情を変更します[p]
;ゆうこの表情の変更
[chara_mod name="yuko" face="angry"]

表情を元に戻します[p]
;ゆうこの表情を元に戻す
[chara_mod name="yuko" face="default"]

					

保存して実行してみましょう。

実行画面


キャラクターの表情が変更されましたね。

[chara_face]タグは chara_newで定義したキャラクターに表情を紐付ける事ができます
つまり、キャラ「yuko」 で 表情「angry」 を使えるようにしました。

次に

[chara_mod name="yuko" face="angry"]

ここでキャラクターの表情を[chara_face]で定義した「angry」に変更しています。
そして、最後に

[chara_mod name="yuko" face="default"]

と記述することで、最初の表情に戻しています。

face="default"の部分ですが default というのは、キャラクターを新規登録した時の表情を指します
このようにすることで、キャラクターの表情を効率的に切り替えてゲームを作成することが出来ます。

登場したキャラクターを画面から退場させる方法をみていきましょう
「haruko」を画面から退場させてみます。以下のスクリプトを追加してください

[chara_hide name="haruko" ]
					

これで、キャラクターは画面から消えましたね？

以上でキャラクター操作に関する解説は終了です。




＞＞次：「選択肢で分岐させよう」へすすむ